Excel VBAでのMultipageの選択

Question

フォーム上に配置したマルチページ（ページタブは３つ有ります）のうち、任意のページをアクティブもしくは選択する方法が分かりません。
例えば、1つ目のページをアクティブにするには、どの様なコードを書けば良いのでしょうか？いろいろ本などで調べましたが、見つかりませんでした。
エクセルのバージョンは97です。よろしくお願いします。

TAGOSAKU7 · Accepted Answer

どもども田吾作７です。

MultiPage1.Value=ページのインデックス値

これでページは切り替わります。

でわでわ

TAGOSAKU7 · Answer

結果からいうと無理です。

別々のCheckBoxは個々単体ですので、VBの基本として、
Object.プロパティやObject.メソッド など、一つのコントロールに対しての命令や属性の変更をかけることしかできません。


もし他の方法を望むのであれば、次のロジックはどうでしょうか？
（これまた参考です。）
手順１．ＥＸＣＥＬ起動時にＵｓｅｒＦｏｒｍをロードしておく
手順２．シート１のCells(1,1)からCells(100,1)の値をＵｓｅｒＦｏｒｍのチェックボックスに反映させる。
手順３．Cells(1,1)からCells(100,1)の値の変更イベント時に、対応するチェックボックスだけ、値を変更する（サンプルモジュールがありますのでそちらを見てください。
手順４．必要なときにＵｓｅｒＦｏｒｍをＳｈｏｗする。
手順５．必要ないときはＵｓｅｒＦｏｒｍをアンロードしないで、Visible=Falseにする。

あとは手順３～５の処理をＥＸＣＥＬが終了するまで繰り返します。


以下のコードをシート１のモジュールに記述してください。
（このサンプルは１～５行目までの変更を認識し、対応するチェックボックスの値を変更します。）
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim wkRange As Range
    
    Set wkRange = Target(1, 1)

    '１列目（Ａ）以外は未処理
    If Not (wkRange.Column = 1) Then GoTo PGMEND
    '５行目以上は未処理
    If (wkRange.Row > 5) Then GoTo PGMEND
    
    UserForm1("CheckBox" & wkRange.Row).Value = (wkRange.Value = 1)
    
PGMEND:
End Sub


毎回たくさんチェックするのがいやなのであれば、こういった方法もありますよ。


でわでわ

TAGOSAKU7 · Answer

どもども 再々度 田吾作７です。


>効率よくチェックしたり、設定するには・・・hogehoge

とありましたが、チェックロジックは全体の処理を知らないと、答えようが・・・

設定は、回答No1のお礼に書いてあったソース部分だけでいうと
For i = 1 to 100 
Userform1("CheckBox" & i).Value = (cells(i, 1).value = 1)
Next i 
ってな感じでいいと思います。
Value に設定してある(cells(i, 1).value = 1)の部分がTrue/Falseを返すので、その値をそのままセットしてやると、If文を使用しないで済むと思います。
（σ(￣ー￣ ボク If文少ないの好きです）



さっきも言ったようにチェックロジックは、全体の処理の流れがわからないと、下手なことを言うことが出来ません。ですので、一応の参考として、チェックロジックのソースを書いておきますが、ご自分の好きなように変更を加えて、今作成中のプログラムに適した形にしてください。

※必要なコントロール
１．コマンドボタン１
２．リストボックス
３．マルチページ
４．マルチページの中にチェックボックスたくさん(各ページにたくさんチェックボックスがあった方が、実験になると思います)


Private Sub CommandButton1_Click()
    With UserForm1
        Call CheckBoxValue_ListBoxOut(.MultiPage1.Pages(0), .ListBox1)
    End With
End Sub

'【機能】リストボックスにマルチページ内の指定ページのチェックボックスの状態を出力
'【パラメータ】
'１．ページオブジェクト
'２．リストボックスオブジェクト
Sub CheckBoxValue_ListBoxOut(inPage As Page, OutListBox As Control)
    Dim wkCtrlCnt   As Long '指定のページに存在するコントロールの数のカウント
    
    Dim wkCheckBox  As Control  'チェックボックスコントロールの一時セットワーク
    
    Dim i   As Long 'ループカウンタ
    
    '出力先リストボックスをクリア
    OutListBox.Clear

    'ページ内のコントロールの数を得る
    wkCtrlCnt = inPage.Controls.Count
    
    'コントロールの数だけループする
    For i = 1 To wkCtrlCnt
    
        'i番目のコントロールのタイプがチェックボックスだった時
        If TypeName(inPage.Controls(i - 1)) = "CheckBox" Then
        
            'ワークに一時セットする(別にセットしないでもかまわないけど、この方が見栄えがよい)
            Set wkCheckBox = inPage.Controls(i - 1)
            'リストボックスへ出力
            OutListBox.AddItem wkCheckBox.Name & " のValueは " & wkCheckBox.Value
            
        End If
    Next i
    
    '開放
    Set wkCheckBox = Nothing
End Sub

あくまでも、参考です・・・

でわでわ

TAGOSAKU7 · Answer

再び田吾作７です。

締め切ってない所を見ると、見てないのか、あるいは「ページのインデックス値 」がわからなかったのかな？

一応参考までに、、、
１番目のタブを指定
MultiPage1.Value=0
２番目のタブを指定
MultiPage1.Value=1
３番目のタブを指定
MultiPage1.Value=2

ってな感じです。

詳しく言うと、各ページはページというオブジェクトで、マルチページとはそのページオブジェクトをコレクション化した（束ねた）ものです。
MultiPage1.Pages(1) とするとページの中を操作しますが、今回したい作業は「どのページをアクティブにするか」ということなので、「このコレクションに対して、どれをアクティブにするか」という命令になります。よってMultiPage1の中のページオブジェクトを操作するのではなく、MultiPage1自身を操作することになります。

それにしても、Valueでページを変更するってのはチョット違和感がありますよね。Microsoftさんの思惑が時々わからなくなるのは僕だけでしょうか？
(￣ロ￣lll) あっ 愚痴ってしまった。。。

でわでわ

Excel VBAでのMultipageの選択

どもども田吾作７です。

結果からいうと無理です。

どもども 再々度 田吾作７です。

再び田吾作７です。

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

今、見られている記事はコレ!

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

どもども再々度田吾作７です。