Excel コードでの簡単な２種類のマクロ実行について

マクロ初心者で詰まってしまっています。バージョンは２０１６です。

コードを利用して二種類のおなじようなマクロを実行したいです。
①１つの範囲内のセルをダブルクリックで２通→１通→ブランク
②（①とは別の）１つの範囲内のセルをダブルクリックで〇→ブランク

２つめのElseIfに対応するIfがないとのエラーが出てしまうのですが、①②をするにはどこを直せばよいのでしょうか。
なお、同様のことを③（別範囲）として行いたいです。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Cancel = True
If Intersect(Target, Range("D5:D50")) Is Nothing Then Exit Sub

Select Case Target.Value
Case ""
Target.Value = "2通"
Case "2通"
Target.Value = "1通"
Case "1通"
Target.Value = ""

Cancel = True

ElseIf Not Application.Intersect(Target, Range("E5:E50")) Is Nothing Then Exit Sub

Select Case Target.Value
Case ""
Target.Value = "〇"
Case "〇"
Target.Value = ""

End Select
End Sub

よろしくお願いいたします。

質問者からの補足コメント

• 

  ありがとうございます！
  Elself をご指摘どおり、If Intersect〜に修正してみたところ、今度は最終のところでselect caseに対応するend selectがありませんとのエラーが出てしまいました…。根本的になにかちがうでしょうか。。

  No.1の回答に寄せられた補足コメントです。 補足日時：2019/01/20 16:48

No.4 ベストアンサー 回答者： WindFaller 回答日時： 2019/01/20 18:28

こんばんは。

インデンティング(indenting-行下げ)をきちんとしていないから、エラーが見つからないのでしょうね。縦で揃えるようにして並べ直しますと、間違っていれば、Select --- End, Select, If ---End if が 揃わなくなります。
アドイン・ツールもあるのですが、今、サイトが開かないようです。
Smart Indenter という名前です。

なるべく、オリジナルを生かしています。
'//
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　If Intersect(Target, Range("D5:E50")) Is Nothing Then Exit Sub
　If Not Intersect(Target, Range("D5:D50")) Is Nothing Then
　　Cancel = True
　　Select Case Target.Value
　　　Case ""
　　　　Target.Value = "2通"
　　　Case "2通"
　　　　Target.Value = "1通"
　　　Case "1通"
　　　　Target.Value = ""
　　End Select
　ElseIf Not Intersect(Target, Range("E5:E50")) Is Nothing Then
　　Cancel = True
　　Select Case Target.Value
　　　Case ""
　　　　Target.Value = "〇"
　　　Case "〇"
　　　　Target.Value = ""
　　End Select
　End If
End Sub

この回答へのお礼

2文目を足してくださったのですね。
確かに位置がよくわからない状況でした。
使用させて頂きました！

お礼日時：2019/01/20 22:21

No.3 回答者： fakeflake 回答日時： 2019/01/20 18:06

最初の、2通1通ブランクを切り替えるSelectに対応するEnd Selectが抜けてますよね。

No.2 回答者： tom04 回答日時： 2019/01/20 18:02

こんにちは！

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　If Intersect(Target, Range("D5:E50")) Is Nothing Then Exit Sub
　　Cancel = True
　　　With Target
　　　　If .Column = 4 Then
　　　　　Select Case .Value
　　　　　　Case ""
　　　　　　　.Value = "2通"
　　　　　　Case "2通"
　　　　　　　.Value = "1通"
　　　　　　Case "1通"
　　　　　　　.Value = ""
　　　　　　End Select
　　　　Else
　　　　　If .Value = "" Then
　　　　　　.Value = "○"
　　　　　Else
　　　　　　.Value = ""
　　　　　End If
　　　　End If
　　　End With
End Sub

こんな感じでどうでしょうか？m(_ _)m

この回答へのお礼

有り難うございます。こちらでも出来そうでした！

お礼日時：2019/01/20 22:18

No.1 回答者： ikejun_2018 回答日時： 2019/01/20 16:28

＞２つめのElseIfに対応するIfがないとのエラーが出てしまうのですが

単に
If Not Application.Intersect(Target, Range("E5:E50")) Is Nothing Then Exit Sub
で良いはずです。
ひょっとしてやりたいことは
If Intersect(Target, Range("E5:E50")) Is Nothing Then Exit Sub
かもしれませんが。

最初の　IF
If Intersect(Target, Range("D5:D50")) Is Nothing Then Exit Sub
の一行で完了していますので
ElseIf　にする必要はありません。