VBA)複数ファイル・シートのデータを一つのシート内に貼り付け

Question

VBAの初心者です。
ネットで使えそうなVBAコードを活用しようとしていますが、アドバイス頂きたいです。

■やりたいこと：
C:\Users	efun\Desktop\Projects\Evaluation
上記フォルダに5つのシートが含まれたソースファイルが22個あります。（3rd_Party_Evaluation_sheet _P1~P22）
各シートの内容は同じで「K1:L1」、「B13:L13」のデータだけ違う内容になっております。

これらを同じフォルダの「Radar_Chart_Index.xlsm」の「3rdParty」というシートに貼り付けていきたいです。
貼り付け対象範囲は、N2:Z111
　1つのソースファイル１シートで１行になりますので
　22ファイル X 5シート　＝　110行
説明の画像を添付しております。

■知りたいこと：
下記コードは、ソースファイル及びコピ元のシートをいちいちマウスで指定しないとならないようになっていますが、
自動で実行するようにはどのように変更したら良いか知りたいです。
初心者で正直下記コードの内容も１００％把握はしておりません。

Sub test1()
    Const f1 = "='C:\Users	efun\Desktop\Projects\Evaluation["
    Const f2 = ".xlsm]P3'!"
    Dim f As String
    Dim i As Long

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
        .Calculation = xlCalculationManual
    End With
    With ActiveSheet
        For i = 1 To 110
            f = f1 & Format$(i, "00") & f2
            .Cells(i + 1, 14).Resize(, 2).Formula = f & "K1"
            .Cells(i + 1, 16).Resize(, 11).Formula = f & "B13"
        Next
        With .Range("N2:O111")
            .Copy
            .PasteSpecial xlPasteValues
        End With
        With .Range("P2:Z111")
            .Copy
            .PasteSpecial xlPasteValues
        End With
    End With
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Qchan1962 · Accepted Answer

こんにちは、
Radar_Chart_Index.xlsmにVBAを書いて良いのでしょうか？
私の読解力が無いためファイル、シート関係が良く理解していませんが、
With .Range("N2:O111")
.Copy
.PasteSpecial xlPasteValues
End With
などで数式を値に変えているなら、初めから値を抽出すれば良いのではないでしょうか、
ただし、対象ファイルを開く必要がありますが。
＞ 5シート
これは、5シートしかないと理解してよいのでしょうか？

手直しは必要と考えますが、
Radar_Chart_Index.xlsmの標準モジュールに一例です。

Sub Test()
　 Const f1 = "C:\Users	efun\Desktop\Projects\Evaluation"
　 Const f2 = ".xlsm"
　 Dim i As Long, TrRow As Long
　 Dim sh As Worksheet, trSh As Worksheet
　 With Application
　　  .ScreenUpdating = False
　　  .EnableEvents = False
　　  .Calculation = xlCalculationManual
　 End With
　 Set sh = Sheets("3rdParty")
　 For i = 1 To 22
　　  With Workbooks.Open(f1 & "3rd_Party_Evaluation_sheet _P" & i & f2)
　　　　For Each trSh In .Worksheets
　　　　　 TrRow = sh.Cells(Rows.Count, "N").End(xlUp).Row + 1
　　　　　 sh.Cells(TrRow, "N").Resize(1, 2).Value = trSh.Range("K1:L1").Value
　　　　　 sh.Cells(TrRow, "P").Resize(1, 11).Value = trSh.Range("B13:L13").Value
　　　　Next trSh
　　　　.Close SaveChanges:=False
　　  End With
　 Next
　 With Application
　　  .Calculation = xlCalculationAutomatic
　　  .EnableEvents = True
　　  .ScreenUpdating = True
　 End With
End Sub

ファイル名は3rd_Party_Evaluation_sheet _P1~P22　で良いのでしょうか？
対象シート数などに問題がある場合は、シート名などを具体的にして補足してくださいね。
未検証の為、コピーファイルなどでお願いします。

VBA)複数ファイル・シートのデータを一つのシート内に貼り付け

こんにちは、

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング