下記マクロでMsgBox "空白です。"の部分の メッセージボックスは現れるものの 空白です。の文字

下記マクロでMsgBox "空白です。"の部分の
メッセージボックスは現れるものの
空白です。の文字が出ません。
原因が分かりません。

全シートの左から3枚目以降のシートを対象に
A3:CEの中にデータが存在するかしないかを調べたいです。
データが残っていれば
ms = ms & vbLf & Sheets(i).Name & "にデータが残っています。" で表示されますが
データが無い場合は画像の通り、文字が出ません。

Sub 残データの確認()
Dim i As Long, cnt As Long, r As Long
Dim rng As Range
Dim ms As String

For i = 3 To Sheets.Count
Sheets(i).Select
With ActiveSheet
r = .UsedRange.Row + ActiveSheet.UsedRange.Rows.Count - 1
If r - 2 = 0 Then
On Error Resume Next
Else
On Error GoTo 0
Set rng = .Range("A3:CE" & r)
If WorksheetFunction.CountA(rng) = 0 Then
cnt = cnt + 1
Else
ms = ms & vbLf & Sheets(i).Name & "にデータが残っています。"
End If
End If
End With
Next i
If cnt = Sheets.Count - 3 Then
MsgBox "空白です。"
Else
MsgBox ms
End If
End Sub

No.3 ベストアンサー 回答者： goomania 回答日時： 2024/06/23 08:26

No.1さん、No.2さんのご指摘のとおりだと思います。

空シート数を数えるのではなく、残データシートの有無をフラグで判定する方法はいかがでしょう。

Sub 残データの確認()
Dim i As Long, r As Long
Dim rng As Range
Dim ms As String
Dim allEmpty As Boolean ' 3シート目以降全シート空のフラグ

allEmpty = True ' フラグを初期化
For i = 3 To Sheets.Count
With Sheets(i)
r = .UsedRange.Rows(.UsedRange.Rows.Count).Row
If r >= 3 Then
Set rng = .Range("A3:CE" & r)
If WorksheetFunction.CountA(rng) > 0 Then
ms = ms & vbLf & .Name & "にデータが残っています。"
allEmpty = False ' フラグを偽に設定
End If
End If
End With
Next i

If allEmpty Then ' 3シート目以降全シート空の場合
MsgBox "空白です。" ' 空白メッセージを表示
Else
MsgBox ms ' 残データがあるシートのメッセージを表示
End If
End Sub

この回答へのお礼

新たにマクロまで組んでいただき
ありがとうございます。
実装してみたところ、見事に思った通りの結果
且つ、高速処理で満足しております。

お礼日時：2024/06/23 10:21

No.2 回答者： zongai 回答日時： 2024/06/22 18:56

3枚目以降で空白なら

cnt = cnt + 1
をするのですから、

ここの判定は -3 ではなく -2 なんじゃないかな。

If cnt = Sheets.Count - 2 Then
　MsgBox "空白です。"
Else

No.1 回答者： fujillin 回答日時： 2024/06/22 18:51

こんばんは

なんだか意図して複雑にしているような・・

＞データが無い場合は画像の通り、文字が出ません。
データがない場合をよく考えてみればわかるはずですけれど・・
　＞MsgBox ms
が実行されるので（変数msの内容は空白文字列）、何も表示されないように見えているだけでしょう。
1シートだけデータを残した状態で実行してみれば、「空白です。」が表示されませんか？