リストボックスの並び替え

VB.NETについて質問です。
ボタン１をクリックしたら、テキストボックス１に入力した文字を、リストボックス１に登録するとします。
この時、名前、年齢を入力します。
これを、ボタン２、３、をクリックしたら、リストボックスの内容を、名前順、年齢順に並べ替えたいです。
どうしても分かりません。
並べ替えるにはどうしたらいいでしょうか？

No.2 ベストアンサー 回答者： herencia 回答日時： 2005/12/19 22:04

下記のコントロールとコードを追加すると実現できます。

他にも方法はあるのですが、自作のコントロールを作る必要があるので、
この方法が簡単だと思います。
前に作っていたものを少し改造したものなのでもしかしたら不具合があるかもしれません。
（エラー処理などは入っていません。
　名前と年齢を一つのテキストで入力したい場合は、
　追加ボタンの処理の箇所で、入力された文字列を分割して設定してください。）

'下記のコントロールをフォームに追加
リストボックスListBox1
テキストボックス（年齢）txtAge
テキストボックス（名前）txtName
ボタン（年齢順）btnSortAge
ボタン（名前順）btnSortName
ボタン（追加）btnAdd
ボタン（削除）btnDel

'------------------------------------------------------
' 下記をフォームの初期処理のコードに追加
' Form1_Load もしくは Public Sub New() の中に追加
'------------------------------------------------------

Call InitListBox()

'------------------------------------------------------
' 下記をフォームのコードに追加
'------------------------------------------------------
Dim mListBoxDtSet As DataSet
Dim mListBoxDtTable As DataTable
Dim mListBoxDtView As DataView

'リストボックス削除処理
Private Function DelListBox(ByVal index As Integer) As Boolean

Dim dtRow() As DataRow
dtRow = mListBoxDtTable.Select("Id = " & index.ToString)
If IsNothing(dtRow(0)) = False Then
mListBoxDtTable.Rows.Remove(dtRow(0))
Return True
Else
Return False
End If

End Function

'リストボックス追加処理（戻り値：追加した項目のIndex＝"Id"）
Private Function AddListBox(ByVal age As Integer, ByVal name As String) As Integer
Dim dtRow As DataRow

dtRow = mListBoxDtTable.NewRow()
dtRow("Age") = age
dtRow("Name") = name
dtRow("DisplayCol") = name & " " & age 'リストボックスへ表示する内容
mListBoxDtTable.Rows.Add(dtRow)

Return CType(dtRow.Item("Id"), Integer)

End Function

'リストボックス初期化処理
Private Sub InitListBox()
'データセット作成
mListBoxDtSet = New DataSet("ListBoxData")
'データテーブル作成
mListBoxDtTable = mListBoxDtSet.Tables.Add("Hito")
Dim pkCol As DataColumn = mListBoxDtTable.Columns.Add("Id", Type.GetType("System.Int32"))
pkCol.AutoIncrement = True
pkCol.AutoIncrementSeed = 1
pkCol.AutoIncrementStep = 1
mListBoxDtTable.Columns.Add("DisplayCol", Type.GetType("System.String"))
mListBoxDtTable.Columns.Add("Age", Type.GetType("System.Int32"))
mListBoxDtTable.Columns.Add("Name", Type.GetType("System.String"))
mListBoxDtTable.PrimaryKey = New DataColumn() {pkCol}
'データビュー作成
mListBoxDtView = New DataView(mListBoxDtSet.Tables("Hito"), "", "", DataViewRowState.CurrentRows)
mListBoxDtView.Sort = "Id"
'リストボックスとデータビューを連結
ListBox1.DataSource = mListBoxDtView
ListBox1.DisplayMember = "DisplayCol"
ListBox1.ValueMember = "Id"

End Sub

'年齢順ボタン＿クリックイベントハンドラ
Private Sub btnSortAge_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSortAge.Click
'降順にしたい場合は"ASC"を"DESC"に変更
mListBoxDtView.Sort = "Age ASC"
End Sub

'名前順ボタン＿クリックイベントハンドラ
Private Sub btnSortName_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSortName.Click
'降順にしたい場合は"ASC"を"DESC"に変更
mListBoxDtView.Sort = "Name ASC"
End Sub

'追加ボタン＿クリックイベントハンドラ
Private Sub btnAdd_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAdd.Click
Call AddListBox(txtAge.Text, txtName.Text)
End Sub

'削除ボタン＿クリックイベントハンドラ
Private Sub btnDel_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnDel.Click
'選択項目存在チェック
If ListBox1.SelectedItems.Count = 0 Then
Exit Sub
End If
'選択項目情報取得
Dim rowId(ListBox1.SelectedItems.Count - 1) As Integer
Dim dtRow As DataRowView
For i As Integer = 0 To ListBox1.SelectedItems.Count - 1
dtRow = CType(ListBox1.SelectedItems(i), DataRowView)
rowId(i) = CType(dtRow("Id"), Integer)
Next
'選択項目該当行削除
For i As Integer = 0 To ListBox1.SelectedItems.Count - 1
Call DelListBox(rowId(i))
Next
End Sub

この回答へのお礼

解決する事が出来ました。
どうもありがとうございました。

お礼日時：2005/12/27 23:00

No.1 回答者： kidanorio 回答日時： 2005/12/19 21:57

これって名前と年齢は、連結したひとつの文字列として入ってしまってますよね？(リストボックスでは複数のフィールドをもてないはずですから・・・ちがったかな？)

だとすると、下のようなっているはず
BBBB 13
CCCC 10
AAAA 12
　　↑
ここにデータ上の境界がない状態

なので、

名前 年齢
AAAA 12
BBBB 13
CCCC 10
こうすることはできますが
CCCC 10
AAAA 12
BBBB 13
こうすることは、できないと思います

名前順だけでよければ
ボタン２押下でリストボックスのSortedプロパティをTrueにしてみてください。(並び変わると思います)

名前、年齢両方の並び替えが必須なのであればリストビューコントロールの使用を検討してみてください。
こちらだと、名前と年齢を別々のフィールドに入れられるので、それぞれで並べ替えられるはずだった気がします。

間違ってたらごめんなさい。
(ほかの方も指摘してくださいね)

この回答へのお礼

プロパティ設定だけでは出来ませんでした。
でも他の方法で解決しました。
どうもありがとうございました。

お礼日時：2005/12/27 23:00