テキストボックスにクエリ結果を表示させたい

フォームにテキストボックスＡがあり、そこに入力した文字（下記テーブルのフィールド１の文字）をクエリーの「抽出条件」にし、同じフォーム上のテキストボックスＢに表示しようと思っています。

クエリを開くとパラメータの入力を求めてきて、入力するとうまく抽出されます。

テーブルは
フィールド１｜フィールド２
　　Ａ　　　｜　　１０
　　Ｂ　　　｜　　２０
　　Ｃ　　　｜　　３０
　　Ｄ　　　｜　　４０
のような簡単なものです。

テキストボックスＢのコントロールソースに
「=[○×クエリ]![フィールド２]とやっても「#Name?」と表示されてしまいます。

どのようにやればよいのでしょうか？

No.1 ベストアンサー 回答者： bonaron 回答日時： 2006/08/19 01:39

クエリは必要ありません。

フォームのレコードソースに無いデータを表示させる
場合には DLookUp を使います。

テキストボックスＢのコントロールソースに
=DLookUp("フィールド２","テーブル名","フィールド１='" & [テキストボックスＡ]) & "'"

上記は「フィールド１」が文字列型の場合です。

数値型の場合は次のようになります。
=DLookUp("フィールド２","テーブル名","フィールド１=" & [テキストボックスＡ])

DLookUp 関数は コントロールソースに限らず
VBA でも使用し、Access では、非常に使用頻度の高いものです。

ヘルプで調べて、ぜひマスターしてください。

もし Access でなかったら、このレスは無視して下さい。

この回答へのお礼

bonaron様
解答有り難うございます。
DLookUp関数の関数のことは知りませんでした。
これからもよく使用していくことになりそうなのでマスターしようと思います。
ありがとうございました。

お礼日時：2006/08/21 10:44

No.2 回答者： noname#22222 回答日時： 2006/08/19 07:30

No1さんの回答が基本。

実行速度を重視するならばADODB を利用する次のステップへ。

=DBLookUp("フィールド２","テーブル名","フィールド１='" & [テキストボックスＡ] & "'")

Public Function DBLookup(ByVal strField As String, _
　　　　　　　　　　　　 ByVal strTable As String, _
　　　　　　　　　　　　 Optional ByVal strWhere As String = "", _
　　　　　　　　　　　　 Optional ByVal ReturnValue = Null) As Variant
On Error GoTo Err_DBLookup
　　 Dim DataValue
　　 Dim strQuerySQL As String
　　 Dim rst　　　　 As ADODB.Recordset

　　 Set rst = New ADODB.Recordset
　　 strQuerySQL = "SELECT " & strField & " FROM " & strTable
　　 If Len(strWhere) > 0 Then
　　　　 strQuerySQL = strQuerySQL & " WHERE " & strWhere
　　 End If
　　 With rst
　　　　 .Open strQuerySQL, _
　　　　　　　 CurrentProject.Connection, _
　　　　　　　 adOpenStatic, _
　　　　　　　 adLockReadOnly
　　　　 If Not .BOF Then
　　　　　　 .MoveFirst
　　　　　　 DataValue = .Fields(0)
　　　　 End If
　　 End With
Exit_DBLookup:
On Error Resume Next
　　 rst.Close
　　 Set rst = Nothing
　　 DBLookup = Nz(DataValue, ReturnValue)
　　 Exit Function
Err_DBLookup:
　　 MsgBox "SELECT 文の実行時にエラーが発生しました。(DBLookup)" & Chr$(13) & Chr$(13) & _
　　　　　　"・Err.Description=" & Err.Description & Chr$(13) & _
　　　　　　"・SQL Text=" & strQuerySQL, _
　　　　　　vbExclamation, " 関数エラーメッセージ"
　　 Resume Exit_DBLookup
End Function

この回答へのお礼

s_husky様
解答有り難うございます。
まだaccessを始めたばかりなのでモジュール関連はもう少し勉強してから使用したいと思います。
そのときには参考にさせて貰います。
今回は有り難うございました。

お礼日時：2006/08/21 10:46