バッチファイルにてFTPで指定したファイルを取得する

OSはWindoswXPProです。
以下のようなBATファイルとバッチファイルを作成しました。

---FTP.bat---
echo off
ftp -s:get.ftp

---get.ftp---
open 10.0.X.X
username
password
cd /log
get log.yymmdd(実際には日付) c:\access_all_log.txt
quit


logというディレクトリには日次でログファイルが作成され
ファイル名としてlog.yymmddと名づけられています。

やりたいことは２つあります。
1つめはftpするファイル名の日付部分をコマンドなどから
範囲指定して取得するファイルを指定できないか。
（たとえば070301～070315のファイルを一括で取得したい）
2つ目はftpでのファイル取得終了後に続いて
バッチスクリプトを流したいのですが、その方法。

お分かりになる方いらっしゃいましたらよろしくお願いいたします。

No.2 ベストアンサー 回答者： ham_kamo 回答日時： 2007/03/19 22:49

バッチで日付を扱うのはけっこう難しいですよね。

VBSで、
・指定した期間内のログファイルをftpでgetするftp.getファイルを生成し、
・getした複数のログファイルを copy で１つのファイル（c:\access_all_log.txt）にまとめ、個々のログファイル(log.yymmdd)を削除するバッチファイルを生成
するスクリプトを作ってみました。

まず、MakeGetFtp.vbs という名前で、以下の内容のファイルをバッチファイルと同じディレクトリに作成してください。（IPアドレス、ユーザ名等は本当のものに書き換えてください）

----------------------------------------------
Dim strDate(2)
Dim argDate(2)
Dim TmpDate,d, i,logfile
Dim FSO,FtpFile,CopyBat
Dim GetStr,CopyStr,DelStr

'引数の数チェック
If WScript.Arguments.Count <> 2 Then
WScript.Echo("開始日付と終了日付を指定してください")
WScript.Quit(1)
End If

'各スクリプト、バッチファイルに渡す日付パラメータの作成
For i = 1 to 2
strDate(i) = Wscript.Arguments.Item(i - 1)
If Not IsNumeric(strDate(i)) or _
Len(strDate(i)) <> 6 Then
WScript.Echo(CStr(i) & "番目の日付の書式が間違っています。")
WScript.Quit(1)
End If
argDate(i) = DateValue("20" & Left(strDate(i),2) & "/" & _
Mid(strDate(i),3,2) & "/" & Right(strDate(i),2))
Next

'初期化
CopyStr = "Copy "
DelStr = "Del "

'FTPのgetコマンド、BATのCOPYコマンド、DELコマンドを作成
For d = argDate(1) to argDate(2)
TmpDate = FormatDateTime(d,2)
TmpDate = Mid(TmpDate,3,2) & Mid(TmpDate,6,2) & Mid(TmpDate,9,2)
logfile = "log." & TmpDate
GetStr = GetStr & "get " & logfile & vbCrlf
CopyStr = CopyStr & logfile & "+"
DelStr = DelStr & logfile & " "
Next

'FTPコマンドをファイルに出力
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile("get.ftp")
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile("get.ftp")
.WriteLine("open 10.0.X.X")
.WriteLine("username")
.WriteLine("password")
.WriteLine("cd /log")
.WriteLine(GetStr)
.WriteLine("quit")
.Close
End With

CopyStr = Left(CopyStr,Len(CopyStr)-1) & " c:\access_all_log.txt"

With FSO.CreateTextFile("TmpCopy.bat")
.WriteLine("@echo off")
.WriteLine(CopyStr)
.WriteLine(DelStr)
.Close
End With

Set FSO = Nothing
----------------------------------------------

そして、FTPを行うバッチファイルを以下の内容にしてください。

----------------------------------------------
@echo off
cscript MakeGetFtp.vbs %1 %2
if %errorlevel% EQU 1 goto end
ftp -s:get.ftp
TmpCopy.bat
:end
----------------------------------------------

上記のバッチファイルの名前を、ftpget.bat とすると、

ftpget.bat 070301 070315
と日付を指定して実行すると、その期間のログをFTPでgetし、c:\access_all_log.txt にまとめられます。

No.3 回答者： ham_kamo 回答日時： 2007/03/20 08:52

No.2です。

すみません、誤記がありました。
MakeGetFtp.vbs の中で、

'FTPコマンドをファイルに出力
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile("get.ftp")
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile("get.ftp")

と同じ２行が繰り返されていますが、これは

'FTPコマンドをファイルに出力
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.CreateTextFile("get.ftp")

と１つだけの誤りでした。

この回答へのお礼

ありがとうございます。
少し遅くなりましたが、完成できました。

お礼日時：2007/05/21 11:55

No.1 回答者： canonbowl 回答日時： 2007/03/19 20:26

参考URL参照

（環境変数の演算->ファイル作成->ftp->ループ）

参考URL：http://www.geocities.jp/clc6249/souko/batchfile/ …