エクセルの「条件付き書式」で困っています

エクセルの「条件付き書式」なんですが
表の見栄えを良くするために、一行ごとに色を付けようと

「書式」--＞「条件付き書式」--＞設定ダイヤログに

条件（1）・・「数式が」-----「=MOD(ROW(),2)=0」を設定しました
　　　　書式--＞パターン・グリーンを指定

思い通り選択範囲の表に、一行ごとの縞模様が出来たのですが

追加で
条件（2）・・「セルの値が」-----「次の値より大きい」-----「１００」
　　　　書式--＞フォント太字・赤を指定

と指定したところセルに色の付いた行（偶数行）は１００以上の数値が入力されても
フォントが太字・赤になりません

このような条件は「条件付き書式」ではなく、表示形式で設定するのでしょうか？

私は「条件付き書式」で一括に設定したいのですが
詳しい方がいらしたら教えて下さい

ＷＩＮ2000・エクセル2000　　です。

No.6 ベストアンサー 回答者： comv 回答日時： 2002/06/22 23:38

再び　こんばんは！

>「Ｎ」はどのような意味を持つのでしょうか

EXCELでは通常の比較では　文字列＞数値　となっています
従って　今回の第３条件　A1>100　とした場合　A1に
文字列を入力した場合でも成り立ってしまいます。

関数　N()　は
　数値であればそのまま返す
　文字列であれば０を返す
関数です。

従って比較演算式で文字列を除外したい場合
参照先が
　大なり　や　以上　を判断する時使い
　小なり　や　以下　を判断する時には使わない
ことになります。

他にも演算時に　文字列を０としてもよいものであれば
エラー回避にも使えます。

この回答へのお礼

なるほど・・・

EXCELでは　文字列＞数値　となるのは「nishi6」様も仰っていたように
仕様なんですね。

それを回避する為ですか、勉強になりました

早速の丁寧な回答ありがとうございます

お礼日時：2002/06/22 23:57

No.5 回答者： comv 回答日時： 2002/06/22 01:09

こんばんは！

条件は３通りになるので

優先順位から
条件１　数式が　=AND(MOD(ROW(),2)=0,N(A1)>100)
　パターン：グリーン　フォント：赤
条件２　数式が　=MOD(ROW(),2)=0
　パターン：グリーン
条件３　数式が　=N(A1)>100
　フォント：赤

となります。

この回答へのお礼

ありがとうございます。

皆様には本当に感謝しています。

他の回答同様、「=AND」をうまく使うのですね
それと
質問なんですが
=AND(MOD(ROW(),2)=0,N(A1)>100) で

「Ｎ」はどのような意味を持つのでしょうか
知らずに使うのも気持ち悪いので

良かったら教えて下さい

お礼日時：2002/06/22 22:57

No.4 回答者： nishi6 回答日時： 2002/06/22 00:43

A1をアクティブセルにしている例です。

条件１は
　数式が、=AND(MOD(ROW(),2)=0,VALUE(A1)>=100)　にして、パターンをグリーン、フォントを太字・赤

条件２は
　数式が、=MOD(ROW(),2)=0　にして、パターンをグリーン　にします。

Excelでは、例えば、A1に文字『A』、B1に数字『10』があれば、A1＞B1 はTrueになります。文字"A"＞数字10 です。
そのために、VALUE(A1)>=100 のようにVALUEをつけた方がいいと思います。
条件付き書式で、『セルの値が、次の値より大きい』を設定し、文字を入力してみると分かると思います。

ご参考に。

この回答へのお礼

ありがとうございます

「papayaku」様、共々皆様に感謝しています。

　「=AND」を付けると言うのは気がつきませんでした
ありがとうございます。

それと、VALUE(A1)>=　をつけた方が良い・・・・これはエクセルの仕様
なんでしょうか

知らなければ疑問の無限ループに陥りそうですね
助かりました

感謝！感謝！です。

お礼日時：2002/06/22 22:50

No.3 回答者： papayuka 回答日時： 2002/06/22 00:15

こんにちは。

訂正です。

条件(1)に数式が「=AND(MOD(ROW(),2)=0,A2>100)」で
パターンをグリーン、フォントを赤の太字

条件(2)に数式が「=(MOD(ROW(),2)=0)」で
パターンをグリーン

にしないとダメでした。

この回答へのお礼

ありがとうございます

なるほど
「=AND」を付けるのには気が付きませんでした

いつも回答者の皆様に感謝しています。
本当に、ありがとうございます。

お礼日時：2002/06/22 22:38

No.2 回答者： arara0123 回答日時： 2002/06/22 00:13

JOXさんこんばんは。

エクセル2000のHELPからの引用です。

・複数の条件を指定する
指定した複数の条件が満たされると、最初に満たされた条件の書式だけが適用されます。

したがって優先的に適用したい条件をはじめに書けば
うまくいくのではないでしょうか？

この回答へのお礼

ありがとうございます

エクセル2000のHELPはあまり使った事がありませんでした
開いても意味不明な文章が多くて・・・・(~~;

でも、これからはなるべくヘルプも覗きます

ありがとうございました

お礼日時：2002/06/22 23:11

No.1 回答者： papayuka 回答日時： 2002/06/22 00:10

こんにちは。

例えば、セルA2だとして、

条件(2)に数式が「=AND(MOD(ROW(),2)=0,A2>100)」で
パターンをグリーン、フォントを赤の太字

にすればどうでしょう。