エクセルで複数の特定の文字列をふくむ行を非表示にしたい。

仕事でエクセル2000を使用しています。

A列に住所が4万件入っているファイルで福岡県と長崎県、愛知県、大阪府の行を表示しないようにしたいと思ってます。
B列に以下の関数を入れて、オートフィルタで０を選択して表示させないように試みました。
=IF(ISERROR(FIND("福岡県",A3)),0,1)
福岡県だけならできますが、他の県を条件に含めるにはどうしたらよいのでしょうか？

この関数にこだわってるわけではありませんので何か別によい方法があれば教えてください。

よろしくおねがいします。

No.6 回答者： mike_g 回答日時： 2008/08/21 17:55

=IF(ISERROR(FIND("福岡県",A3))+ISERROR(FIND("長崎県",A3))+ISERROR(FIND(

"愛知県",A3))+ISERROR(FIND("大阪府",A3))<4,0,1)

この回答へのお礼

ありがとうございます。

こういう式もあるのですね。
関数をもっと勉強します。

お礼日時：2008/08/21 21:44

No.5 回答者： Wendy02 回答日時： 2008/08/21 16:16

こんにちは。

>オートフィルタでは2つまでの条件しか指定できないのであきらめたのです。

フィルタオプションでいけます。

最初に、ありきたりですが、
住所 ←タイトル名（フィールド名）が必要です。
福岡県***


空いている場所の２行目に
以下のような式を入れます。

=SUMPRODUCT(COUNTIF(A2,{"福岡県*","長崎県*","愛知県*","大阪府*"}))=0

検索式は、A2 からで、A1ではありません。下にコピーする必要はありません。この数式は一つでよいのです。そして、この式は、True でも、False でも関係ありません。

設定は、

データのあるA列にもマウス・カーソルを置いてから、

[データ]--[フィルタオプションの設定]（何かメッセージが出ても無視）

[リスト範囲]は自動で入るはずです。

[検索条件範囲]に、
例えば、
$F$1:$F$2 (先ほど作った、数式がF2 に入り、F1 は、空にしておきます）

そうすれば、オートフィルタを使ったように出てきます。
これは、領域の使用が少なくて済みます。

まずは、試してみてください。

この回答へのお礼

ありがとうございます。

結果に感動しました！びっくりです。
まだどうしてそうなるのかよくわからないのですが
こんな方法があるのですね。

お礼日時：2008/08/21 21:37

No.4 ベストアンサー 回答者： maron--5 回答日時： 2008/08/21 15:50

◆こんな方法もありますよ

★別の列に
=COUNT(FIND({"福岡県","長崎県","愛知県","大阪府"},A1))
★下にコピー
★オートフィルターで0を抽出

この回答へのお礼

ありがとうございます！
この関数は思いつきませんでした。

さすがですね。

お礼日時：2008/08/21 21:25

No.3 回答者： onlyrom 回答日時： 2008/08/21 15:32

いやはやとんでもない回答をしてしまいました。

お許しあれ。
仰るようにオートフィルターでは条件は２つですねぇ。(^^;;;

解決されたようですが、参考までに。。。

●ツールメニュー　＞　フィルターオブションの設定

でやってください。
これなら汎用的なものが出来ます。
使い方は表示されるダイアログを見れば分かると思います。

以上。
　

この回答へのお礼

ありがとうございます。
フィルターオプションの設定は今まであまり使ったことが
なかったので。

まだまだ使いこなせてないことを改めて実感しました。

お礼日時：2008/08/21 21:28

No.2 回答者： onlyrom 回答日時： 2008/08/21 14:07

作業列を使わないでも次のようにすればできませんか。

１．セルＡ１を選択する
２．データメニュー　＞　オートフィルター　と進む
３．Ａ１の▼ボタンをクリックし表示されるリストで（オプション）を選択
４．オプションダイアログで以下のようにする

（左のボックス）　　　（右のボックス）
＿＿福岡県＿＿　　　　　等しくない
＿＿長崎県＿＿　　　　　等しくない
　　　
　　　　　＜＜以下同様＞＞

５．ＯＫボタン


外しましたらご容赦！
以上。

この回答へのお礼

ご回答ありがとうございます。

オートフィルタでは2つまでの条件しか指定できないのであきらめたのです。

お礼日時：2008/08/21 14:25

No.1 回答者： keirika 回答日時： 2008/08/21 13:56

=IF(ISERROR(FIND("福岡県",A3)),0,1)+IF(ISERROR(FIND("長崎県",A3)),0,1)+IF(ISERROR(FIND("愛知県",A3)),0,1)+IF(ISERROR(FIND("大阪府",A3)),0,1)

でオートフィルターで0を抽出でどうでしょう。

この回答へのお礼

ありがとうございます。
解決しました！
どこに＋をいれるのかわからず、関数を短くするために無理やりFINDのカッコ内に複数の県をプラスでいれようとしてエラーになってました。

ちゃんと関数を勉強しないとだめですね。

お礼日時：2008/08/21 14:08