2つの条件を満たした金額を合計するには？【画像あり】

こんにちは、みなさん!!

【質問】
下記の画像をご覧ください。２つの条件を満たした金額を合計したいのですが、良い関数はありますでしょうか？
　２つの条件とは分類Ａ→【１００】、日時→【約】　という文字が含まれるものです。
　イメージは黄色く塗りつぶしたセルのように計算される事です。

ご存知の方いらっしゃいましたらよろしくお願いします。

No.3 ベストアンサー 回答者： Wendy02 回答日時： 2009/08/21 16:44

こんにちは。

このようにすればどうでしょうか？

=SUMPRODUCT((A2:A6=100)*(RIGHT(B2:B6,1)="約")*C2:C6)

No.6 回答者： tom04 回答日時： 2009/08/21 22:21

こんばんは！

すでに回答は出ていますので・・・
参考程度で目を通してみてください。

↓の画像のように作業列を使った方法になります。

D2セルに
=IF(COUNTIF(B2,"*約*")>0,"○","")
という数式をいれてオートフィルで下にコピーします。

そして、C8セルに
=SUMPRODUCT((A2:A6=100)*(D2:D6="○"),C2:C6)

という数式を入れています。

以上、参考になれば幸いです。m(__)m

No.5 回答者： imogasi 回答日時： 2009/08/21 21:58

２条件の足しこみ、毎日このコーナーに出てくる質問で、答える気もでない。

ＳＵＭＰＲＯＤＵＣＴ関数
２００７ではＳＵＭＩＦＳ関数で（だからエクセルバージョンを書くこと）
Ｇｏｏｇｌｅで「エクセル　ＳＵＭＰＲＯＤＵＣＴ」で照会して勉強のこと。たくさん記事が出る。
ーー
100の方は=100
「約」の方は、文字列に「含まれる」と言うことなので、
Countif(範囲,"*約"）
かＮＯＴ（ＩＳＥＲＲＯＲ（ＦＩＮＤ（"約",・・、）））を使う。
ここがこの質問の新味。
ーー
例データ
分類成約金額
1009/15約1
2008/152
3008/15返3
4008/164
1009/20約5
6008/176
注意　8/17などは文字列でいれたもの。日付シリアル値で入れると話が違う。
ーー
式は　=SUMPRODUCT((A2:A10=100)*(NOT(ISERROR(FIND("約",B2:B10))))*(C2:C10))
結果
６

No.4 回答者： hallo-2007 回答日時： 2009/08/21 19:20

複数の条件でという事ですので、これを機会に配列関数を勉強してみてはいかがですか。

B列で　約　という文字を含んでいるかどうかですが、
ISNUMBER(FIND("約",B2))　とFIND関数で　約　という文字を探させて
きちんと数値が返ってくるかどうかで判断させます。

=SUM((A2:A6=100)*ISNUMBER(FIND("約",B2:B6))*C2:C6)
上記の式を入れて　Ctrl+Shift+Enterで決定すると　式が{}でくくられて配列関数として認識されます。
A2:A6が100の場合に　TRUE　つまり　1です。（それ以外は　0）
同様に、B2：B6に約という文字が含まれれば　1　それ以外は　0
それに、C2:C6の数値を掛け算するので、条件にあった行はC列の値
条件に合わなければ　0が掛け算されるので、　０になります。
SUM関数でその結果の合計になります。
配列関数の使い方を理解すれば応用の範囲が広がります。

No.2 回答者： cistronezk 回答日時： 2009/08/21 16:17

このページの右側に「この質問に関するQ&A」にもありますが、こちらが参考になるでしょう。

http://questionbox.jp.msn.com/qa3609278.html
例によってExcelのバージョンが不明ですが、2007ならSUMIFS関数が使えます。
http://www.becoolusers.com/excel/sumifs.html

No.1 回答者： JavaJavax2 回答日時： 2009/08/21 15:27

http://www.eurus.dti.ne.jp/~yoneyama/Excel/kansu …

が参考になるのでは？画像がありませんが？