下位５個の平均を求める関数式が分かりません。

下位５個の平均を求める関数式が分かりません。
複数の関数式でしたら作れましたが、１つの関数式で出来ませんので、１つの式か２つの式にしたいです。

自分で作成した式は以下のようになりました。
=SMALL(F3:F1992,1)
=SMALL(F3:F1992,2)
=SMALL(F3:F1992,3)
=SMALL(F3:F1992,4)
=SMALL(F3:F1992,5)
=ROUND(AVERAGE(M90:M94),0)
SMALL関数で下位５個を出しまして、それらの平均を求めましたが、これでは式が６つになってしまいます。
１つか２つの関数式に出来ますでしょうか。
１つの式の方がありがたいです。
よろしくお願いします。

No.5 回答者： sige1701 回答日時： 2010/02/04 22:48

追加で

>下位５個
の個数が増大することを考慮して

=ROUND(AVERAGE(SMALL(F3:F1992,ROW(1:5))),0)
配列数式です

この回答へのお礼

ご配慮、ありがとうございます。

こちらの式では、出したい数値になりませんでしたので、No.4の式を使いたいと思います。

皆様、どうもありがとうございました。

お礼日時：2010/02/05 00:43

No.4 ベストアンサー 回答者： sige1701 回答日時： 2010/02/04 22:41

こんな感じでいいかな

=ROUND(AVERAGE(SMALL(F3:F1992,{1,2,3,4,5})),0)

この回答へのお礼

ありがとうございます。
すっきりした式に出来るのですね。

お礼日時：2010/02/05 00:37

No.3 回答者： usami33 回答日時： 2010/02/04 22:35

下位２個の例・・・判りますよね

=(SMALL(A1:A4,1) + SMALL(A1:A4,2))/2

この回答へのお礼

ありがとうございます。
５個足して５で割れば出ますね。

お礼日時：2010/02/05 00:28

No.2 回答者： himajin100000 回答日時： 2010/02/04 22:34

=SUMPRODUCT((RANK(A1:A6,$A$1:$A$6,1) <= 5) * A1:A6) / 5

A1 = 1
A2 = 2
A3 = 7
A4 = 4
A5 = 5
A6 = 3
で3(なお、1 + 2 + 3 + 4 + 5 = 15,15 / 3 = 5)
とか。Excel 2003で確認。

#ただ、boolからlongヘの変換があって、
OOoはtrueを1であると保証してなかった気がするので
本当はうまい書き方がほしいんだけど以前やったときにうまく書けなかった覚えがある。いまだにExcelの数式の規則性がよくわかってない。

この回答へのお礼

ありがとうございます。
このような書き方もあるのですね。

お礼日時：2010/02/05 00:34

No.1 回答者： edomin7777 回答日時： 2010/02/04 22:26

=ROUND(AVERAGE(SMALL(F3:F1992,1),SMALL(F3:F1992,2),SMALL(F3:F1992,3),SMALL(F3:F1992,4),SMALL(F3:F1992,5)),0)

は？

この回答へのお礼

出来ました。
どうもありがとうございました。

お礼日時：2010/02/05 00:07