Excel関数：文字を含む複数条件の合計 （2）

「AA」の文字を含むA社の合計(=8)、しかし、そのうち「例外」の文字が含まれている場合(該当4) は合計から除く方法を教えていただけますでしょうか。

　　　　　A　　　　　　　　　　B　　　　C　　　D　　　　E　　　　F
　　―――――――――――――――――――――――――
1　｜商品名　　　　　　　　A社　　B社　　C社　　 A社　　B社
2　｜AA　　　　　　　　　　　1　　　　1　　　　1　　　　1　　　　1
3　｜BB　　　　　　　　　　　1　　　　1　　　　1　　　　1　　　　1
4　｜ab　AA　　　　　　　 　1　　　　1　　　　1　　　　1　　　　1
5　｜ab　BB 　　　　　　　　1　　　　1　　　　1　　　　1　　　　1
6　｜ab　AA　例外　　 　　1　　　　1　　　　1　　　　1　　　　1
7　｜ab　BB　例外　　 　　1　　　　1　　　　1　　　　1　　　　1
8　｜ab　AA　12　例外　　1　　　　1　　　　1　　　　1　　　　1
9　｜ab　BB　12　例外　　1　　　　1　　　　1　　　　1　　　　1

つい先日、「AA」の文字を含むA社の合計(=8) については教えていただき解決することができました。
=SUMPRODUCT((ISNUMBER(FIND("AA",A2:A9)))*(B1:F1="A社")*(B2:F9))

今度はこれに 「例外」の文字が含まれる値は合計せず、「4」を導き出す数式は可能でしょうか。
※件数カウントではありません。

よろしくお願いいたします！

No.2 ベストアンサー 回答者： KURUMITO 回答日時： 2012/08/08 16:53

同じような式でしたら次の式にすればよいでしょう。

=SUMPRODUCT((ISNUMBER(FIND("AA",A2:A9)))*(ISERROR(FIND("例外",A2:A9)))*(B1:F1="A社")*(B2:F9))

この回答へのお礼

早々のご回答ありがとうございました。

早速入力してみたところ、できました！

関数の凄さと、KURUMITOさまの知識の高さに感動しました。
本当にありがとうございました！

お礼日時：2012/08/08 18:04

No.3 回答者： keithin 回答日時： 2012/08/08 22:33

わざわざそんなにムズカシイ式にしなくても、普段使いの関数だけで出来ますが？

ＡＡを含むＡ社の合計：
=SUMIF($A:$A,"*AA*",B:B)
ＡＡと例外で終わるＡ社の合計：
=SUMIF($A:$A,"*AA*例外",B:B)

差し引けば欲しい答えが得られます。ちなみに答えは４じゃありません。
必要に応じて右にコピーすれば、Ｂ社Ｃ社も求まります。



「Ａ社」の列位置も計算で求めたいなら、もうちょいと応用して：
=SUMIF(A:A,"*AA*",INDEX(B:F,0,MATCH("Ａ社",B1:F1,0)))-SUMIF(A:A,"*AA*例外",INDEX(B:F,0,MATCH("Ａ社",B1:F1,0)))

この回答へのお礼

お礼が遅くなり申し訳ございません。
SUMIFでの求め方も大変参考になりました。
複数列ででてくるA社の合計を求めたいと思っていましたので
2つ目の式を参考にし活用させていただきます。
お忙しい中ご回答いただき、誠にありがとうございました。

お礼日時：2012/08/14 14:57

No.1 回答者： atamagawarui5 回答日時： 2012/08/08 15:22

SUMIFS関数使ってください。

この回答へのお礼

早々のご回答ありがとうございました！

SUMIFS であれば複数条件の集計が可能なのですね。
初めて知りました。（素人で申し訳ございません）

調べてみたところ、私の会社PCはOffice2003であったため
SUMIFS が使えませんでした(涙)
今後の参考にさせていただきます。

お礼日時：2012/08/08 18:02