access2007でツールバーの変更方法が分かるページは

Ａｃｃｅｓｓ２００３のデータベースで作成したツールバーをＡｃｃｅｓｓ２００７に
変換するとリボンのアドインの中で使用が可能になりますが・・・

このアドインの内容を変更するやり方が書いてあるようなページはありますでしょうか。
やりたいのは単にボタンをクリックされた時に実行されるマクロを変更したい、
あるいはあるマクロを実行するボタンをもう一つ追加したいといった程度です。
こういったことの説明があるページなどをご存じでしたら、ＵＲＬを教えて頂けません
でしょうか。

リボンの中で複雑な指定をするなどということは考えてはいません。

No.1 ベストアンサー 回答者： bonaron 回答日時： 2015/09/17 18:12

2007 以降、ユーザー設定がありませんから

VBA でやることになります。

新しいツールバーを作る
http://officetanaka.net/excel/vba/tips/tips54.htm
http://www.happy2-island.com/access/gogo03/capte …
などが参考になるかな。

・新規ツールバー作成のサンプル
Sub AddToolBar()
　　Dim cbrCmd As CommandBar
　　Dim cbrCtrl As CommandBarControl

　　'ツールバー用のオブジェクトを作ります
　　Set cbrCmd = Application.CommandBars.Add(Name:="私のツールバー")

　　'ボタンを追加し、表題を設定します
　　Set cbrCtrl = cbrCmd.Controls.Add(Type:=msoControlButton)
　　With cbrCtrl
　　　　.Caption = "マクロ1の実行"
　　　　.OnAction = "テストマクロ.マクロ1"
　　　　.Style = msoButtonCaption
　　End With

　　Set cbrCtrl = cbrCmd.Controls.Add(Type:=msoControlButton)
　　With cbrCtrl
　　　　.Caption = "マクロ2の実行"
　　　　.OnAction = "テストマクロ.マクロ2"
　　　　.Style = msoButtonCaption
　　End With

　　cbrCmd.Visible = True

　　Set cbrCtrl = Nothing
　　Set cbrCmd = Nothing
End Sub

・作成したツールバーを変更するサンプル
Sub EditToolBar()
　　Dim cbrCmd As CommandBar
　　Dim cbrCtrl As CommandBarControl

　　 'ツールバーのオブジェクトを作ります
　　Set cbrCmd = Application.CommandBars("私のツールバー")

　　'ボタンを編集します
　　Set cbrCtrl = cbrCmd.Controls(1) '1番目のボタン
　　With cbrCtrl
　　　　.Caption = "本番マクロ"
　　　　.OnAction = "本番マクロ"
　　End With

　　'ボタンを追加し、表題を設定します
　　Set cbrCtrl = cbrCmd.Controls.Add(Type:=msoControlButton)
　　With cbrCtrl
　　　　.Caption = "マクロ3の実行"
　　　　.OnAction = "マクロ3"
　　　　.Style = msoButtonCaption
　　End With

　　Set cbrCtrl = Nothing
　　Set cbrCmd = Nothing
End Sub

※エラー処理が入ってないので、
2度、同じ名前のツールバーを作成するとエラーになります。
イミデイエイトウィンドウで
CommandBars("私のツールバー").Delete
を実行すれば、削除できます。

この回答へのお礼

bonaron様
大変ありがとうございます。
とても分かりやすそうなページで、やってみようという
気持ちがとても湧いてきました。
丁寧な説明もとてもありがたいです。
いま、少しわくわくした気持ちで、希望が湧いてきました。
ありがとうございました。

お礼日時：2015/09/17 20:38