エクセルで和暦を数列に変換する方法

はじめて質問させて頂きます。
エクセル2010で、次のように和暦＋月日を数列に変換したいです。

例えば)

平成25年6月17日を

1=明治、2=大正、3=昭和、4=平成 → 4

25年→25

6月→06

17日→17

→→4250617に変換したいです

どうぞよろしくお願いします。

質問者からの補足コメント

• 使うのは主に平成で、たぶん元はシリアル値だと思います。
  変換後は7桁の数字にしたいです。
  その後、数式を使って利用する予定です

    補足日時：2017/12/25 20:23

No.5 ベストアンサー 回答者： GooUserラック 回答日時： 2017/12/25 22:22

こんなのはいかがでしょうか？

「=VALUE(MATCH(TEXT(A1,"g"),{"M","T","S","H"},0)&TEXT(A1,"eemmdd"))」

この回答へのお礼

ありがとうございました！この式をいれてみたら出来ました‼

お礼日時：2017/12/26 20:36

No.7 回答者： mike_g 回答日時： 2017/12/25 22:55

=(FIND(TEXT(A1,"g"),"MTSH")&TEXT(A1,"emmdd"))+0

この回答へのお礼

ありがとうございます

お礼日時：2017/12/26 20:35

No.6 回答者： WindFaller 回答日時： 2017/12/25 22:50

平成25年6月17日 が、

シリアル値なら、
=FIND(TEXT(A1,"g"),"MTSH")&TEXT(A1,"eemmdd")


文字列だとしたら、
=FIND(TEXT(A1*1,"g"),"MTSH")&TEXT(A1*1,"eemmdd")

この回答へのお礼

ありがとうございます

お礼日時：2017/12/26 20:35

No.4 回答者： tom04 回答日時： 2017/12/25 21:26

No.2です。

＞数式を使って利用する予定です。

一案です。↓の画像のようにD～F列に対応表を作成してみました。
E列は各元号の始まりの日になります。
これは　頭の　1～4　を決めるのに使います。
（仮に1989/1/７までは昭和ですが、1989/1/8から平成になります）

F列は和暦の「年」を割り出すために使います。

画像ではB1セル（セルの表示形式は標準にしておく）に
=IF(A1="","",MATCH(A1,E:E,1)*10^6+(YEAR(A1)-VLOOKUP(A1,E:F,2,1))*10^4+MONTH(A1)*100+DAY(A1))

という数式を入れフィルハンドルで下へコピーしています。

※　細かい検証はしていません。m(_ _)m

No.3 回答者： GooUserラック 回答日時： 2017/12/25 19:52

追加確認です。

エクセルで通常扱える日付は1900年1月1日（明治33年1月1日）以降です。
元は文字列でしょうか？それともシリアル値でしょうか？

ちなみにエクセルは1900年3月1日（明治33年3月1日）より前は、1900年2月29日（明治33年2月29日）を持っている為、日付計算や曜日計算が狂います。ただしマクロ（ＶＢＡ）では正しく扱えます。

No.2 回答者： tom04 回答日時： 2017/12/25 19:48

こんばんは！

A1セルに「平成25年6月17日」のシリアル値が入っているとします。
B1セルに
=MATCH(TEXT(A1,"ggg"),{"明治","大正","昭和","平成"},0)&TEXT(A1,"emmdd")

ではどうでしょうか？

※　表示された数値は文字列になりますので、
計算等には利用できません。m(_ _)m

No.1 回答者： GooUserラック 回答日時： 2017/12/25 19:25

① 変換後は文字列の数列でしょうか？それとも７桁の数値でしょうか？

② 数式が良いですか？それともマクロ（ＶＢＡ）で変換しますか？