【VBA】エクセルで選択した範囲の値のみをクリップボードにコピーするコードについて

VBAの初心者です。
エクセル2016を使っておりますが，選択した範囲（複数セル）の値のみをクリップボードにコピーするマクロをご教示願います。

検索すると，以下のものが出てきますが，走らせると止まってしまいます。

https://qiita.com/tukiyo3/items/0d50f2834fb5098b …

Sub copy_e6()
'
' copy_e6 Macro
'

Dim myDO As New DataObject
myDO.SetText Range("E6").Value
myDO.PutInClipboard

End Sub

No.3 ベストアンサー 回答者： Qchan1962 回答日時： 2023/03/08 19:55

横から失礼します

少し難しい回答かもしれませんが
参照設定については　後にして　貼り付け先（使用用途は）どこなのでしょう
＞値のみをクリップボードにコピーする

サンプルは単セルですがExcelのセル範囲を選択して実行している場合
列方向　vbTab 行方向 vbCrlfが必要になるのではないかと思います
（各値をただ繋げるなら不要ですが）

以下サンプル
実行時参照でDataObjectを使っていますが　エラーになるかも知れません

Sub copy_e6()
'
' copy_e6 Macro
'
Dim ary As Variant
ary = Selection.Value '選択範囲の値を一旦配列に格納
' Dim myDO As New DataObject
Dim myDO As Object
Set myDO = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
Dim i As Long, j As Long
Dim strBuf As String
For i = 1 To UBound(ary, 1)
For j = 1 To UBound(ary, 2)
strBuf = strBuf & ary(i, j) & vbTab
Next
strBuf = Left(strBuf, Len(strBuf) - 1) '右のタブコードを削除
strBuf = strBuf & vbCrLf '改行コードを付加
Next
myDO.SetText strBuf
myDO.PutInClipboard
Set myDO = Nothing
End Sub

配列に入れている理由　
オブジェクトやコレクションをループするEachのループ方向は信頼できないと聞いたことがあるので　カラム＞＞行　の順序を確定する為

参照設定については　こちらを参考にしてみてください
NJ-CLUCKER
https://nj-clucker.com/excel/references-ms-forms …

参照設定が正しく出来た場合は（このままでも良いですが）
Dim myDO As New DataObject　の方を使用して

Dim myDO As Object
Set myDO = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
は削除してください

この回答へのお礼

誠にありがとうございます。
確認したところ，うまく走りました。

お礼日時：2023/03/09 16:43

No.2 回答者： ミラ-_- 回答日時： 2023/03/08 18:05

MSFormsライブラリが読み込まれていない可能性があります。

以下の手順に従って、ライブラリを読み込んでから、コードを実行してください。

Excelを開いて、Visual Basic Editorを開きます。

[ツール]メニューから[参照設定]をクリックします。

[参照設定]ダイアログボックスで、[Microsoft Forms 2.0 Object Library]を選択します。

[OK]ボタンをクリックして、ダイアログボックスを閉じます。


以下は、選択範囲の値と数式を両方コピーするために改良されたコードです。

Sub CopySelectedValuesAndFormulasToClipboard()

Dim dataObj As New MSForms.DataObject
Dim selectedRange As Range
Dim cell As Range
Dim outputString As String

Set selectedRange = Selection

' Loop through each cell in the selected range and append its value or formula to the output string.
For Each cell In selectedRange.Cells
If cell.HasFormula Then
outputString = outputString & cell.Formula & vbTab
Else
outputString = outputString & cell.Value & vbTab
End If
Next cell

' Remove the trailing tab character from the output string.
outputString = Left(outputString, Len(outputString) - 1)

' Copy the output string to the clipboard.
dataObj.SetText outputString
dataObj.PutInClipboard

End Sub

このコードでは、HasFormulaプロパティを使用して、セルが数式を持つかどうかをチェックし、必要に応じて値または数式をコピーします。コードを実行する前に、選択範囲内に数式が含まれていることを確認してください。

この回答へのお礼

ありがとうございます。

しかし，「[参照設定]ダイアログボックスで、[Microsoft Forms 2.0 Object Library]を選択します。」とのことですが，[Microsoft Forms 16.0 Object Library]はあっても，[Microsoft Forms 2.0 Object Library]が選択項目としてありません。
[Microsoft Forms 16.0 Object Library]にチェックをした状態で，書いていただいたコードを走らせると，前回と同じく「コンパイルエラー：ユーザ定義型は定義されていません」と出て止まってしまいます。

何がダメなのでしょうか。。
ご教示いただけると幸いです。

お礼日時：2023/03/08 18:36

No.1 回答者： ミラ-_- 回答日時： 2023/03/08 17:48

Sub CopySelectedValuesToClipboard()

Dim dataObj As New MSForms.DataObject
Dim selectedRange As Range
Dim cell As Range
Dim outputString As String

Set selectedRange = Selection

' Loop through each cell in the selected range and append its value to the output string.
For Each cell In selectedRange.Cells
outputString = outputString & cell.Value & vbTab
Next cell

' Remove the trailing tab character from the output string.
outputString = Left(outputString, Len(outputString) - 1)

' Copy the output string to the clipboard.
dataObj.SetText outputString
dataObj.PutInClipboard
End Sub


Alt + F8を押して、マクロの実行ウィンドウを開きます。
CopySelectedValuesToClipboardを選択して、実行をクリックします。
クリップボードに選択した範囲の値がコピーされます。
注意：このマクロは、選択範囲内のすべてのセルの値をクリップボードにコピーします。セルに数式が含まれている場合は、その数式がコピーされます。数式の結果のみをコピーする場合は、セルの値を手動でコピーする必要があります。

この回答へのお礼

ありがとうございます。

申し訳ないのですが，選択範囲には数式が多数含まれており，それについても値でコピーしたいです。

また，教えていただいたコードを実行してみましたがうまく動きません。
「コンパイルエラー：ユーザ定義型は定義されていません」と表示されます。そのときに，２行目の「dataObj As New MSForms.DataObject」が選択された状態になっています。

お礼日時：2023/03/08 17:57