10進数を5進数に変換する式

A1=1,A2=3,A3=5・・・(10進数)とした場合、B1=1,B2=3,B3=10・・・(5進数)のように変換するときオートフィルで100列まで表示したいのです。
どのような式になるでしょうか。
回答よろしくお願いします。

No.2 ベストアンサー 回答者： Yosha 回答日時： 2009/02/19 03:42

>オートフィルで100列まで表示したいのです

オートフィルで処理したいとのことなので、関数の組み合わせで解決するようにします。

Ａ列に入る数の最大値が不明なので、最大値を区切って話を進めます。　いずれも　Ｂ1　に入れオートフィルします。

=MOD($A1,5)　：　0～４までの数を表示します。　ＭＡＸ＝４

=MOD(TRUNC($A1/5),5)*10+MOD($A1,5)　：　表示　０～４４　：　ＭＡＸ＝２４

これを

=MOD(TRUNC($A1/5^1),5)*10^1+MOD($A1,5)　のように書き換えます。　

ちなみに、最初の　MOD($A1,5)　は　MOD(TRUNC($A1/5^0),5)*10^0　と同じです。


=MOD(TRUNC($A2/5^2),5)*10^2+MOD(TRUNC($A2/5^1),5)*10^1+MOD($A2,5)　：　表示　0～444　：　ＭＡＸ＝１２４

ここまで、お分かりかと思いますが、規則性が見えてきましたね。　
１桁＝５^n 増す毎に、　MOD(TRUNC($A2/5^n),5)*10^n 　の　n　を１つずつ増加したものを加算していくだけです。

変換する前の数の最大値は、５＾（ｎ + 1)　-　1　です。　変換後の桁数は ｎ + 1 です。

n が　６　の式は次の通り。

=MOD(TRUNC($A1/5^6),5)*10^6+MOD(TRUNC($A1/5^5),5)*10^5+MOD(TRUNC($A1/5^4),5)*10^4+MOD(TRUNC($A1/5^3),5)*10^3+MOD(TRUNC($A1/5^2),5)*10^2+MOD(TRUNC($A1/5^1),5)*10^1+MOD($A1,5)

ついでに、ｎ　と　変換前の数値の最大値を列記します。

　ｎ　　　　　最大値　　　　　　変換後の最大値
　０　　　　　　　　　　４　　　　　　　　　　　４
　１　　　　　　　　　２４　　　　　　　　　　４４
　２　　　　　　　　１２４　　　　　　　　　４４４
　３　　　　　　　　６２４　　　　　　　　４４４４
　４　　　　　　３，１２４　　　　　　　４４４４４
　５　　　　　１５，６２４　　　　　　４４４４４４
　６　　　　　７５，１２４　　　　　４４４４４４４
　７　　　　３９０，６２４　　　　４４４４４４４４
　８　　１，９５３，１２４　　　４４４４４４４４４
　９　　９，７６５，６２４　　４４４４４４４４４４

実際に扱う最大数によって、式を変更しオートフィルしてください。

No.1 回答者： webuser 回答日時： 2009/02/19 02:50

10進数→8進数と同じ考えでできるのでは？

5で割り続けて余りを並べるだけです。
何回割れるかはループさせないと分かりませんのでマクロ組む方がてっとり早いですが、
100列までという制限があるので、その桁分を固定で用意すれば良いです。

100÷5=20余り0
20÷5=4余り0
4÷5=0余り4
つまり400です。
3桁で行けます。


MOD(A, 5) = １桁目
MOD(A÷5, 5) = ２桁目
MOD(A÷5÷5, 5) = ３桁目
です。

MOD(A, 5) × 1 【１桁目】
＋
MOD(A÷5, 5) × 10 = 【２桁目】
＋
MOD(A÷5÷5, 5) × 100 = 【３桁目】
なので、

これに少数を切り捨てる細工をして

=MOD(A1,5)+MOD(INT(A1/5),5)*10+MOD(INT(INT(A1/5)/5),5)*100