デスクトップ上のアイコンの位置の取得

いつもお世話になってます。
皆様の知恵をお借りできればと思います。

やりたいことは、
デスクトップ上にあるアイコンの座標を知り、たとえばデスクトップの真ん中にアイコンを移動する。
そういったことがしたいのですが、ネットを探してもなかなかサンプルと呼べるものがなく、質問させていただきました。
皆さんよろしくおねがいします。

No.4 ベストアンサー 回答者： tsukasa-12r 回答日時： 2009/12/16 22:18

前回の記載内容にいくつか誤りがありましたので訂正します。

下のコードは Windows XP + Excel 200 VBA で動作確認しました。
VB6 でも、同様にすれば動作すると思います。

Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindow Lib "user32.dll" (ByVal hWnd As Long, ByVal uCmd As Long) As Long
Private Declare Function ListView_GetItemRect Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal MSG As Long, ByVal lngIndex As Long, ByRef rc As RECT) As Long
Private Declare Function ListView_SetItemPosition Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal MSG As Long, ByVal lngIndex As Long, ByVal lngPosition As Long) As Long

Private Type LVITEM
mask As Long
iItem As Long
iSubItem As Long
state As Long
stateMask As Long
pszText As Long
cchTextMax As Long
iImage As Long
lParam As Long
iIndent As Long
End Type

Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Private Const LVM_GETITEMRECT As Long = &H100E
Private Const LVM_SETITEMPOSITION As Long = &H100F
Private Const GW_CHILD As Long = 5
Private Const LVIR_ICON As Long = 1

Private Sub CommandButton1_Click()
Dim lngTopWindow As Long
Dim lngChildWindow As Long
Dim lngSysListView32 As Long
Dim lvi As LVITEM
Dim rc As RECT

lngTopWindow = FindWindow("Progman", "Program Manager")
If lngTopWindow Then
lngChildWindow = GetWindow(lngTopWindow, GW_CHILD)
If lngChildWindow Then
lngSysListView32 = GetWindow(lngChildWindow, GW_CHILD)
If lngSysListView32 Then

' インデックス＝ 0 のアイコンの位置を取得します。
rc.Left = LVIR_ICON
ListView_GetItemRect lngSysListView32, LVM_GETITEMRECT, 0, rc

' X 方向に +100 移動させます
ListView_SetItemPosition lngSysListView32, LVM_SETITEMPOSITION, 0, rc.Top * &H10000 + rc.Left + 100

End If
End If
End If
End Sub

この回答へのお礼

おぉぉぉぉぉ！！！！
できました！！

ほんっとにありがとうございました！！！

お礼日時：2009/12/18 10:01

No.3 回答者： tsukasa-12r 回答日時： 2009/12/16 13:08

ご使用のソフトは何でしょう？

VB6とVBAは比較的似ていますが、VB.NETはVB6、VBAとはかなり異なった仕様となっています。
とは言っても、いずれにせよ WIN32API を使用することになると思います。
ソースコードではなく概略だけ書きます。

1. API の FindWindowを使用して、
クラス名：Program
タイトル：FolderView
のウインドウのハンドルを取得します。(Windows7で確認した内容なので、他のWindowsでは違っているかもしれません。)
2. API の GetWindowを使用して 1.の子ウインドウのハンドルを取得します。
3. API の GetWindowを使用して 2.の子ウインドウのハンドルを取得します。(このハンドルが SysListView32 になります。)
4. 3. のハンドルに対してAPI の SendMessage で LVM_GETITEMRECT を送り、アイコンの位置を取得します。
5. アイコンの位置を変数するには 3. のハンドルに対してAPI の SendMessage で LVM_SETITEMPOSISION を送ります。

この回答への補足

すいません。使用環境はVB6です。

補足日時：2009/12/16 15:06

No.2 回答者： AlexSuns 回答日時： 2009/12/15 21:21

SysListView32を調べてみると幸せになれるかも

この回答への補足

SysListView32は調べてみたんですが・・・。自分にはどうもレベルが高すぎです（泣）
SysListView32のサンプル的なソースはないですか？

補足日時：2009/12/16 08:36

No.1 回答者： dondoko4 回答日時： 2009/12/15 21:13

アイコンにの座標というのが分かりませんが、真ん中にアイコンを持ってくることは簡単です。

アイコンの自動整列を外せば良い。
好きなところに置けます。