ActionScript2.0の変数をjs置き換え

Question

こんにちは。

現在、ActionScript2.0を使用して時間をカウントするFLASHを制作しています。

大体は完成したのですが、一点お聞きしたいことがあります。

ターゲットの時間を

var targetDate:Date = new Date(年,月,日,時,分,秒);

としているのですが、swfを使い回したいため、
時間だけをjavascriptで設定したいと考えています。

そこで、

「new Date(年,月,日,時,分,秒);」　（若しくは、「年,月,日,時,分,秒」だけ）

の部分をjavascriptで置き換えたいと考えています。

調べると、ExternalInterfaceクラスやgetURLを使用すると可能なようなのですが、
チャレンジしても実装できませんでした。。

具体的な記述方法をご教授頂けましたら幸いです。

どうぞよろしくお願いいたします。

BlurFiltan · Accepted Answer

＃１＆２です。

> 「〇〇年〇〇月〇〇日〇〇時〇〇分〇〇秒」を
> ターゲットに、現在の時間からカウントダウン

そういうことですね。
それでしたら次のような感じになるのではないでしょうか。

以下は＃１の補足で書かれたものをベースに変更しています。

HTML
---------------------------
<html>
<head>
<title>test</title>
<script type="text/javascript">

function sayTime() {
//2010年12月1日0時をターゲットとする
var targetDate = new Date(2010,11,1,0,0,0);
var targetTime = targetDate.getTime();
return targetTime;
}

</script>
</head>
<body>



</object>
</body>
</html>
---------------------------

swfファイルActionScript
---------------------------
//externalクラスのインポート
import flash.external.*;

//1フレームで停止
stop();

//JavaScriptからターゲットのミリ秒数を取得
var jsTime:Number = Number(ExternalInterface.call("sayTime"));

this.onEnterFrame = function() {
//
//現在のローカル日付オブジェクトを作成
var today:Date = new Date();
//
//1971年1月1日から現在のミリ秒数を取得
var myTime:Number = today.getTime();
//
//JavaScriptで得たミリ秒数から現在のミリ秒数を引いた残り
var timeLeft:Number = jsTime - myTime;
//その残りを秒にしておく
var secLeft = Math.ceil(timeLeft / 1000);
//
//残り時間のそれぞれ日・時・分・秒を割り出す
var days:Number = Math.floor(secLeft / (24 * 60 * 60));
secLeft -= days * 24 * 60 * 60;
var hrs:Number = Math.floor(secLeft / (60 * 60));
secLeft -= hrs * 60 * 60;
var min:Number = Math.floor(secLeft / 60);
secLeft -= min * 60;
var sec:Number = secLeft;
//
//日を文字列に変換
var counter_days:String = String(days);
//時を2桁文字列に変換
var counter_hrs:String = ("0" + hrs).substr(-2, 2);
//分を2桁文字列に変換
var counter_mins:String = ("0" + min).substr(-2, 2);
//秒を2桁文字列に変換
var counter_secs:String = ("0" + sec).substr(-2, 2);
//
//各テキストフィールドに日・時・分・秒を表示
_root.time_days.text = counter_days;
_root.time_hrs.text = counter_hrs;
_root.time_mins.text = counter_mins;
_root.time_secs.text = counter_secs;
//
//カウントダウン終了時2フレームへ
if (timeLeft <= 0) {
delete this.onEnterFrame;
gotoAndStop(2);
}
};
---------------------------

※次の図は日・時・分・秒を求めるイメージ図です。
※＃２の下に substr() についての図も追加しました。

BlurFiltan · Answer

> 思うように動かすことが出来ません。。。

と書かれましても，
何がどう動くことが「思うように動く」の状態なのかわからないため
解決策も，問題点すらもわかりませんよ。。。

文字数制限で書けなかったのでしょうか？
（私は ＃１ も，この ＃２ の回答も字数制限ほぼいっぱいですが。）

「思う/思わない」とか「うまく行く/行かない」などという主観でなく
なるべく「何がどうなっていてそれをどうさせようとしているのか」という客観的な情報を書いてください。

補足で書かれていらっしゃることについての
根本的な大前提の質問です。

書かれた補足では
＃１で私が書いたスクリプトよりも複雑になったスクリプトを書かれていらっしゃいますが
それは 
「ExternalInterface の件はもう大丈夫だから次の問題点へ質問を変える。」 という意味なのでしょうか？
それとも
「ExternalInterface の件は大丈夫だったが，スクリプトを変えると JavaScript との連携ができなくなった。」  という意味なのでしょうか？
それとも
「ExternalInterface の件も大丈夫ではないが，その点は置いておいてスクリプトを変えた。」   という意味なのでしょうか？

「ExternalInterface で JavaScript とのやりとりができたのかできなかったのか。」
その点すら書かれていらっしゃらないのですよ。
「思うように」 とは一体何のお話なのかがわかりません。

===スクリプトの感想==================

検証もしてませんし細かい部分も見ていませんが
ザッと見，次の部分は明らかに変（ナンセンス）だと思いました。

this.onEnterFrame = function(){
　　～略～
　　//JavaScriptからターゲットのミリ秒数を取得
　　var jsTime:Number = Number(ExternalInterface.call("sayTime"));
　　～略～
}

これだと
onEnterFrame で ExternalInterface.call が実行され続けます。
ExternalInterface.call で得られる結果は変わらないにも関わらずです。
全く同じ値を得るために 毎フレーム時間(１秒間に十数回～数十回も) ExternalInterface.call が実行されるんですよ。

ダブルで変です。
「全く同じ値だと決まっているもの何度も請求する」のが変です。
また仮に同じ値ではないとしても
「ブラウザのプログラムであるJavaScriptを頻繁に叩く(ボコボコに連打して返事を請求し続ける)」のが変です。

ExternalInterface.call は最初に１回実行すれば良いだけです。
onEnterFrame の中ではなく前に出しましょう。

仮に JavaScript から送られる値が頻繁に変わるものであったとしても
最初の call によってその後の値が推測できる場合は Flash で計算すべきです。
（「最初の値は推測できないが，その後の値は１秒毎に１ずつが上がる規則がある」などの場合は当然 Flash でその後の値を計算すべき。）
（その後の値を推測できなかったとしても onEnterFrame は やり過ぎ。）

BlurFiltan · Answer

JavaScript で次のように書いた場合

var targetDate = new Date(年,月,日,時,分,秒);

これで生成される targetDate は JavaScript の Dateオブジェクトであって
JavaScript 内だけで通用するものです。
(JavaScript だけが理解できる Dateクラスという概念に属するオブジェクト)
そういうものはやりとりできません。

ですから例えば
　JavaScript で作成した Dateオブジェクトから
　getTime() で1971年１月１日からミリ秒など取得し
　その数値（や文字列）を他言語(Flashなど)に送る。
というようなことをする必要があります。

◎HTMLソースコード例
---------------------------
<html>
<head>
<title>test</title>
<script type="text/javascript">

function sayTime() {
var targetDate = new Date(2010,10,18,19,7,5);
var targetTime = targetDate.getTime();
return targetTime;
}

</script>
</head>
<body>



</body>
</html>
---------------------------

◎上記HTMLに貼り付けるSWFの
　フレームに書く ActionScript 例
---------------------------
//externalクラスのインポート
import flash.external.*;

//JavaScriptからミリ秒数を取得
var jsTime:Number = Number(ExternalInterface.call("sayTime"));

//取得した時刻のDateオブジェクトを作成
var myDate:Date = new Date(jsTime);

var ye:Number = myDate.getFullYear();
var mo:Number = myDate.getMonth() + 1;
var da:Number = myDate.getDate();
var ho:Number = myDate.getHours();
var mi:Number = myDate.getMinutes();
var se:Number = myDate.getSeconds();

//テキストフィールドでも用意して表示してみる
createTextField("time_txt", 0, 10, 20, 300, 20);
time_txt.border = true;
time_txt.text = ye + "年" + mo + "月" + da + "日" + ho + "時" + mi + "分" + se + "秒";
---------------------------

※要：Flash Player 8 以上用の SWF パブリッシュ

上記HTMLをブラウザで開けば結果を見ることができると思います。

===または======

JavaScript の function を次のように変え，

function sayTime() {
return "2010,10,18,19,7,5";
}

そして
ActionScript の時刻取得部分を次のように変えても良いと思います。

～以上略～
var jsTime:String = String(ExternalInterface.call("sayTime"));
var arr:Array = jsTime.split(",");

var myDate:Date = new Date();

myDate.setFullYear(arr[0]);
myDate.setMonth(arr[1]);
myDate.setDate(arr[2]);
myDate.setHours(arr[3]);
myDate.setMinutes(arr[4]);
myDate.setSeconds(arr[5]);

var ye:Number = myDate.getFullYear();
～以下略～

ActionScript2.0の変数をjs置き換え

＃１＆２です。

> 思うように動かすことが出来ません。

この回答への補足

JavaScript で次のように書いた場合

この回答への補足

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング