常に最下行を表示する方法

Question

こんばんわ。
　
データをエクセル上にリアルタイムにロギングしていくソフトを使用しているのですがデータが上段から下段へ移行していきます。
上段から下段へ移動するのは問題ないのですが
データが入力されるにつれモニター画面を通り越してしまうので最新データを常に見ていることができません。
最新データを常に見れるように最下段に入ったデータを常にモニター画面に表示できるようにできないでしょうか？

因みに私が扱ってるデータは一秒間に５回くらい入力されます。
エクセル2000を使用していますが5万行くらいのデータ量になります。
どうぞご教授のほどよろしくお願いします。

keithin · Accepted Answer

なるほど。
それではANo.2で回答したマクロを

Private Sub Worksheet_Change(ByVal Target As Range)
　on error resume next
　Target.Offset(1).Select
End Sub

とします。
このマクロは，ロギングが走っているシートごとにシート名タブを右クリックして，コードの表示を選んで現れたシートに貼り付けます。

ki-aaa · Answer

標準モジュールの出し方。
　Sheet見出し上で右クリック　→　コードの表示　→　VBE画面が出ますので
　その画面で、挿入をクリック　→　標準モジュールを選択
　出てきた画面に貼り付けしてください。

マクロの実行方法
　キーボードの[Alt]と[F8]を押します。
　実行したいものを選択します。

コメントを書き加えましたので、読んでください

'ここから
Option Explicit

Private Declare Function GetAsyncKeyState Lib "user32" ( _
ByVal vKey As Long) As Integer

Private 呼び出し回数 As Long

Sub スクロールサブ()
　　Dim i As Long
　　Const myName = "Sheet1"  'スクロールしたいシートの名前に変更する
　　If ActiveSheet.Name = myName Then
　　　　i = Range("A" & Rows.Count).End(xlUp).Row  'A列の最終行をセット。列が違ったら"A"を"B"などに書き換える
　　　　ActiveWindow.ScrollRow = i
　　　　If GetAsyncKeyState(vbKeyEscape) <> 0 Then  'Escを2秒以上押すと実行停止
　　　　　　呼び出し回数 = 0
　　　　　　Application.StatusBar = False
　　　　　　Exit Sub
　　　　End If
　　　　If 呼び出し回数 < 0 Then
　　　　　　呼び出し回数 = 0
　　　　　　Exit Sub
　　　　End If
　　End If
　　'2秒毎に自分自身を呼び出し、スクロールする
　　Application.OnTime Now + TimeValue("00:00:02"), "スクロールサブ"
　　呼び出し回数 = 呼び出し回数 + 1
　　Application.StatusBar = _
　　　　　"呼び出し回数... " & 呼び出し回数
End Sub

Sub 繰り返し停止サブ()
　　呼び出し回数 = -1000
　　Application.StatusBar = False
End Sub

ki-aaa · Answer

こんな方法はどうでしょうか

標準モジュール

Option Explicit

Private Declare Function GetAsyncKeyState Lib "user32" ( _
ByVal vKey As Long) As Integer

Private 呼び出し回数 As Long

Sub スクロールサブ()
　　Dim i As Long
　　i = ActiveSheet.UsedRange.Rows.Count
　　ActiveWindow.ScrollRow = i
　　If GetAsyncKeyState(vbKeyEscape) <> 0 Then  'Escapeが現在押されている状態だったら実行停止
　　　　呼び出し回数 = 0
　　　　Application.StatusBar = False
　　　　Exit Sub
　　End If
　　If 呼び出し回数 < 0 Then
　　　　呼び出し回数 = 0
　　　　Exit Sub
　　End If
　　Application.OnTime Now + TimeValue("00:00:02"), "スクロールサブ"
　　呼び出し回数 = 呼び出し回数 + 1
　　Application.StatusBar = _
　　　　　"呼び出し回数... " & 呼び出し回数
End Sub

Sub 繰り返し停止サブ()
　　呼び出し回数 = -1000
　　Application.StatusBar = False
End Sub

keithin · Answer

シート名タブを右クリックしてコードの表示を選び

Private Sub Worksheet_Change(ByVal Target As Range)
Target.Offset(1).Select
End Sub

とかでいいです。

tom04 · Answer

こんばんは！
一例です。

画面左下にある操作したいSheet見出し上で右クリック　→　コードの表示　→　VBE画面が出ますので、
↓のコードをコピー＆ペーストしてみてください。

Private Sub Worksheet_Change(ByVal Target As Range) 'この行から
    Dim i As Long
    i = ActiveSheet.UsedRange.Rows.Count
     ActiveWindow.ScrollRow = i
End Sub 'この行まで

尚、最終行が画面の1行目に表示されてしまいますので、仮に最終行を画面の10行目に表示したい場合は

ActiveWindow.ScrollRow = i　　の部分を

ActiveWindow.ScrollRow = i-9

のように調整してみてください。
参考になれば良いのですが・・・m(__)m

常に最下行を表示する方法

なるほど。

標準モジュールの出し方。

こんな方法はどうでしょうか

シート名タブを右クリックしてコードの表示を選び

こんばんは！

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング