アプリ版：「スタンプのみでお礼する」機能のリリースについて

急いでいます！

ExcelVBA テキストファイルUNICODE文字化けについて

解決済

  • 質問者：6ass3eu6
  • 質問日時：
  • 回答数：14件

1.環境
Microsoft Windows7 64ビット
Microsoft Ofiice2013 Excel2013 32ビット

2.事象
テキストファイルに定義しているUNICODEを読むと文字化け(?)します。
メモ帳等のテキストファイル上はUNICODEを文字化けせずに目視で確認しています。
どうしたら文字化けせずに読めるのでしょうか？
どなたか詳しい方、ご教授願います。

3.テキストファイル(test.dat)
❶

4.VBA
・参照設定([ツール(T)]バー－[参照設定(R)…])
レ Microsoft ActiveX Data Objects 2.8 Library

・ソース
※例どっちでも、文字化けします。
Dim a, b As String
例1)
With CreateObject("ADODB.Stream")
.Charset = "UTF-8"
.Type = adTypeText
.Open
.LoadFromFile "C:\test.dat"
a = .ReadText
.Close
End With

例2)
Open "C:\test.dat" For Input As #1
Do Until EOF(1)
Line Input #1, b
Loop
Close #1

質問者からの補足コメント

  • うーん・・・

    UTF-16LEに変更して実行後、下記のエラーが出ました。
    困っています。
    解消方法を願います。

    ■エラー詳細
    Err.Number：3001
    Err.Description：引数が間違った型、許容範囲外、または競合しています。

    No.1の回答に寄せられた補足コメントです。 補足日時：2016/09/16 11:43
    通報する

  • どう思う？

    64ビット版の秀丸エディタで、開きました。
    次に[メニュー]バー－[ファイル]－[名前を付けて保存(A)…]
    名前を付けて保存画面
    エンコードの種類(C): [自動判定 - Unicode(UTF-8)] □BOMを付ける(※チェック無)

    No.2の回答に寄せられた補足コメントです。 補足日時：2016/09/16 14:26
    通報する

  • どう思う？

    Unicode(UTF-8) BOMはグレー表示（ＢＯＭ無）になっています。
    開いたファイルの内容は、秀丸できちんと表示されています。

    No.3の回答に寄せられた補足コメントです。 補足日時：2016/09/16 15:13
    通報する

  • うーん・・・

    ソースの提供ありがとうございました。
    下記のようにして参照設定を変更してソース実行をしました。

    まだ、文字化け(?)をします。
    ちなみに試しに①は、文字化け(?)をせずにきちんと表示されました。
    また、Microsoft ActiveX Data Objects 2.8 Libraryに戻して、実行も文字化けしています。
    後、例１の実行も文字化けしています。

    ■参照設定の変更
    ・参照設定([ツール(T)]バー－[参照設定(R)…])
    レ Microsoft ActiveX Data Objects 6.1 Library

    No.5の回答に寄せられた補足コメントです。 補足日時：2016/09/16 16:20
    通報する

  • うーん・・・

    皆さん、様々な情報ありがとうございます。
    秀丸で❶を改行付き、Unicode16(UTF-16)　□BOMを付ける(※チェック有)で保存

    > この文字をexcelのシートに直接出力すれば、きちんと表示されます。
    結果は文字化けです。
    (◆◆の中に(?)v')が見れました。
    > ・読み込んだテキストがどんな文字列になっているか、1文字1文字ascWでコードを調べる
    -3でした。
    > Shift_JISに無い「黒地の丸数字」が変換できずに「文字化け」になっている、というものです。
    と自分も思います。
    書き忘れていたのですが、したい事はExcelVBAを通して別のテキストファイルに❶を出力させる事です。
    今の文字化け状態で別のテキストファイルにそのまま出力で、あるソフト変換にて正しく表示出来ればＯＫです。
    果たしてそのUnicodeを維持していればいいのですが…

    No.9の回答に寄せられた補足コメントです。 補足日時：2016/09/18 18:13
    通報する

  • うれしい

    皆さんのアドバイスを元に色々、試しました。
    結果、NGです。
    発想を変えて、入力テキストファイルから出力テキストファイルではなく、シートのセルから出力テキストファイルに変更しました。
    結果、OKです。
    これは、セル自体にUnicodeを対応していると思っています。
    自分だけでは、解決出来ず、皆さんのアドバイズに感謝しています。
    ありがとうございました(__)。

      補足日時：2016/09/22 10:52
    通報する
通報する

この質問への回答は締め切られました。

質問の本文を隠す

A 回答 (14件中1～10件)

No.1

(例1) 実は読み込んでいるファイル、UTF-8じゃなくてUTF-16LEだったとかいうオチじゃないよね？

この回答への補足あり
    • good
    • 0
    • 件
通報する

No.2

  • 回答者： tatsu99
  • 回答日時：

そのテキストファイル(test.dat)が一体、どのＵＮＩＣＯＤＥなのかを明確にする必要があります。


もし、秀丸があれば、秀丸で、そのファイルを開いてください。
UTF-16(LE) BOM無
UTF-16(BE)　BOM無
UTF-7　BOM無
UTF-16(LE) BOM付き
UTF-16(BE)　BOM付き
UTF-7　BOM付き
等が考えられますが、まず、どのＵＮＩＣＯＤＥなのかを明らかにしましょう。
話はそれからです。
この回答への補足あり
    • good
    • 0
    • 件
通報する

No.3

  • 回答者： tatsu99
  • 回答日時：

UTF-8 BOM無のように見えますが、念の為


（１）秀丸でそのファイルを開いて、
メニューバーの「ファイル」ー「エンコードの種類」で
Unicode(UTF-8) BOMはグレー表示（ＢＯＭ無）
となっていますか。
（２）開いたファイルの内容は、秀丸できちんと表示されていますか。
この回答への補足あり
    • good
    • 0
    • 件
通報する

No.4

  • 回答者： tatsu99
  • 回答日時：

ファイルがＵＴＦ－８の前提です。


以下のようにしてください。
---------------------------------------------------
Option Explicit

Public Sub Macro1()
Call myReadFile("c:\test.data")
End Sub
'参照設定でMicrosoft ActiveX Data Objects x.x Library（最新版） にチェックをしておくこと
Public Sub myReadFile(ByVal infile As String)
'読み込み用オブジェクト作成
'ファイルを読み込むための変数
Dim line As String
Dim lineNo As Long
'オブジェクトを作成
Dim txt As Object
Set txt = CreateObject("ADODB.Stream")
'オブジェクトに保存するデータの種類を文字列型に指定する
txt.Type = adTypeText
'文字列型のオブジェクトの文字コードを指定する
txt.Charset = "UTF-8"
'オブジェクトのインスタンスを作成
txt.Open

'ファイルからデータを読み込む
txt.LoadFromFile (infile)
lineNo& = 0
'最終行までループする
Do While Not txt.EOS
lineNo = lineNo + 1
'1行を読み取る
line = txt.ReadText(adReadLine)
MsgBox (line)
Loop

txt.Close
'メモリからオブジェクトを削除する
Set txt = Nothing

MsgBox ("lineNo=" & lineNo)
End Sub
------------------------------------------------------
１行ずつ読み込んで、メッセージボックスに内容を表示しています。
参照設定でMicrosoft ActiveX Data Objects x.x Library（最新版） にチェックをしておくことを
忘れずにお願いいたします。
    • good
    • 0
    • 件
通報する

No.5

  • 回答者： tatsu99
  • 回答日時：

No4です。


あなたの例１のソースをこちらで実行してみました。（適当なＵＴＦ－８のテキストファイルを作成し、それを読み込み）
きちんと読み込めています。
こちらの環境は
Windows7 64Bit
Excel2007
Microsoft ActiveX Data Objects 2.8 Library
で、確認しました。
プログラムは正しいように思えます。
データに問題があるように思えますが、もし、（セキュリティ上）可能なら、そのデータを
外部から参照できるようにしていただければ、更に進展があるかもしれません。
もし、それができない場合は、
簡単なＵＴＦ－８のファイルを作成し、例１のプログラムでそれを読み込んで確認されてはいかがでしょうか。
そうすれば、すくなくとも、プログラムは正しいということの検証は可能かと思います。
この回答への補足あり
    • good
    • 0
    • 件
通報する

No.6

  • 回答者： tatsu99
  • 回答日時：

No5です。


>まだ、文字化け(?)をします。
>ちなみに試しに①は、文字化け(?)をせずにきちんと表示されました。

文字化けを起こすのはデータが原因の可能性がかなり高いです。
文字化けを起こすテキストファイル(test.dat)は、何行程度のデータでしょうか？
私が提供したソースで文字化けを起こすのは、何行目でしょうか。
もし、その行が特定できれば、その行（またはその部分）だけを提示していただければ、こちらでも
参照できるので、何とかなるかも知れません。
以下の何れかの方法が取れれば、進展が望めますが、そうでない場合は、（申し訳ありませんが）
他の回答者（例えば過去に同じような問題に遭遇し、解決したことがある人）の回答を待つ以外に方法はないかと思います。
（１）文字化けを起こすデータをそのファイルのまま公開する。
（２）文字化けを起こす箇所を特定し、その箇所を公開する。
    • good
    • 0
    • 件
通報する

No.7

  • 回答者： WindFaller
  • 回答日時：

アップロードしたつもりでしたが、載っていませんので、ちょっと試してみてください。

　[参照設定、Microsoft ActiveX Data Objects 2.8 Library]

以下は、LE BE も、両方とも通ります。
UTF-8 は、.Charset = "UTF-8" にしてみてくたざい。


'//
Sub Test1()
Dim iStream As New ADODB.Stream
Const MYPATH = "C:\Temp\Test1\"
With iStream
　.Open
　.Type = 2
　.Charset = "UNICODE"
　.LoadFromFile MYPATH & "UTF-16LE_09016.txt"
End With
Dim oStream As New ADODB.Stream
With oStream
　.Open
　.Type = 2
　.Charset = "SHIFT-JIS"
　iStream.CopyTo oStream
　.SaveToFile MYPATH & "JIS0916_test.txt", 2
　iStream.Close
End With
Set iStream = Nothing
　oStream.Close
Set oStream = Nothing
End Sub
    • good
    • 0
    • 件
通報する

No.8

  • 回答者： kmee
  • 回答日時：

小手先だけでやろうとしても、無理が出るものです。


具体的に、どんな化け方しているか、調査しましょう。

「文字化けしている」ということを、どうやって確認しましたか?
　質問にあるコードには、ファイルの読み込みしかありません。
　これをセルに代入したり、MsgBox等で表示したり、ファイルに書き込んだりしたときに、始めて「文字化けしている」と認識できるはずです。

・ ❶ は文字化けする
・ ① は文字化けしない
だと、考えられるのは、 出力までの間に、どこかで「Shift_JIS(正確にはCP932)」を経由していて、Shift_JISに無い「黒地の丸数字」が変換できずに「文字化け」になっている、というものです。


まず、入力が期待通りなのかを調べましょう
・入力ファイルをバイナリエディタで開いて、どんなバイト列になっているか調べる
・それが想像通りか調べる。
・読み込んだテキストがどんな文字列になっているか、1文字1文字ascWでコードを調べる
    • good
    • 0
    • 件
通報する

No.9

  • 回答者： tatsu99
  • 回答日時：

No6です。


すみません。❶の文字が文字化けのように？で表示され、①はきちんと表示されるということですね。
この理由は、No8の方が言われているとおり、❶はUNICODEにあるが、SHIFT-JISにはないために発生しています。
文字化けが発生しているように見えるのは、メッセージボックス、とかテキストボックスのテキストは、SHIFT－JISで表示しているためです。
VBAは内部の文字をUNICODE16(LE)で保持していますので、内部では文字化けは発生していません。
メッセージボックス、とかテキストボックスに表示したときのみ、？が表示されます。
この文字をexcelのシートに直接出力すれば、きちんと表示されます。
以下のコードを試してください。
---------------------------------------------------
Option Explicit
Public Sub Macro1()
Call myReadFile("D:\goo\excel\goo11.txt")
End Sub
'参照設定でMicrosoft ActiveX Data Objects x.x Library（最新版） にチェックをしておくこと
Public Sub myReadFile(ByVal infile As String)
'読み込み用オブジェクト作成
'ファイルを読み込むための変数
Dim line As String
Dim lineNo As Long
'オブジェクトを作成
Dim txt As Object
Set txt = CreateObject("ADODB.Stream")
'オブジェクトに保存するデータの種類を文字列型に指定する
txt.Type = adTypeText
'文字列型のオブジェクトの文字コードを指定する
txt.Charset = "UTF-8"
'オブジェクトのインスタンスを作成
txt.Open

'ファイルからデータを読み込む
txt.LoadFromFile (infile)
lineNo = 0
'最終行までループする
Do While Not txt.EOS
lineNo = lineNo + 1
'1行を読み取る
line = txt.ReadText(adReadLine)
ThisWorkbook.ActiveSheet.Cells(lineNo, 1).Value = line
Loop

txt.Close
'メモリからオブジェクトを削除する
Set txt = Nothing

MsgBox ("lineNo=" & lineNo)
End Sub
--------------------------------------------------------------------
該当シートのA列の各行に読み込んだ内容が格納され、きちんと表示されます。
この回答への補足あり
    • good
    • 0
    • 件
通報する

No.10

  • 回答者： tatsu99
  • 回答日時：

No9です。


>結果は文字化けです。
>(◆◆の中に(?)v')が見れました。
うーむ・・・。こちらではきちんと表示されます。

>書き忘れていたのですが、したい事はExcelVBAを通して別のテキストファイルに❶を出力させる事です。
>今の文字化け状態で別のテキストファイルにそのまま出力で、あるソフト変換にて正しく表示出来ればＯＫです。
以下に示すのが、
入力ファイル：UTF-8（BOM付き）
出力ファイル：UTF-8（BOM付き）
の仕様で、1行単位で入力ファイルを読み込み、1行単位で出力するプログラムです。
これで、入力ファイルと出力ファイルが全く同じであれば、あなたが必要とする要件は満たせると思います。
以下のようになります。
------------------------------------------------------
Option Explicit
Public Sub Macro2()
Call myCopyFile("D:\goo\excel\goo11.txt", "D:\goo\excel\goo11_out.txt")
End Sub
'参照設定でMicrosoft ActiveX Data Objects x.x Library（最新版） にチェックをしておくこと
Public Sub myCopyFile(ByVal infile As String, ByVal outFile As String)
'読み込み用オブジェクト作成
'ファイルを読み込むための変数
Dim line As String
Dim lineNo As Long
'オブジェクトを作成
Dim txt As Object
Set txt = CreateObject("ADODB.Stream")
'オブジェクトに保存するデータの種類を文字列型に指定する
txt.Type = adTypeText
'文字列型のオブジェクトの文字コードを指定する
txt.Charset = "UTF-8"
'オブジェクトのインスタンスを作成
txt.Open

'書き込み用オブジェクト作成
Dim txt2 As Object
Set txt2 = CreateObject("ADODB.Stream")
'オブジェクトに保存するデータの種類を文字列型に指定する
txt2.Type = adTypeText
'文字列型のオブジェクトの文字コードを指定する
txt2.Charset = "UTF-8"
'オブジェクトのインスタンスを作成
txt2.Open

'ファイルからデータを読み込む
txt.LoadFromFile (infile)
lineNo& = 0
'最終行までループする
Do While Not txt.EOS
lineNo = lineNo + 1
'1行を読み取る
line = txt.ReadText(adReadLine)
'1行を書き込み用オブジェクトへ書き込み
txt2.WriteText line, adWriteLine
Loop
'書き込みオブジェクトの内容をファイルに保存
txt2.SaveToFile (outFile), adSaveCreateOverWrite
'オブジェクトを閉じる
txt2.Close
txt.Close
'メモリからオブジェクトを削除する
Set txt2 = Nothing
Set txt = Nothing

MsgBox ("lineNo=" & lineNo&)
End Sub
-----------------------------------------------
入力ファイルと出力ファイルがバイナリレベルで同じであることを
コマンドプロンプトで
fc /b 入力ファイル 出力ファイル
上記コマンドで確認済みです。
テストデータ(goo11.txt)は、下記の2行です。
--------------------
❶
①
--------------------

もし、出力ファイルがBOM無であることを望まれる場合は、ファイルの先頭３バイトを削除する必要があるため、
更に別の処理が必要になります。その場合は、その旨、補足ください。とりあえずは、上記のプログラムで
ファイルが正常にコピーできることを確認していただけますでしょうか。
    • good
    • 0
    • 件
通報する

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう！

Q質問する（無料）

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

ページトップページトップ

Q質問する（無料）

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

おすすめ情報