エクセル。１から１２が循環。

お世話になります。
下記内容をエクセルの計算式で可能ですか？

A１に１と入力→B1,C1に２　３と反映

６と入力→７　８と反映

１２と入力→１　２と反映

言葉足らずな点は補足いたします。
よろしくお願いいたします。

No.6 ベストアンサー 回答者： WindFaller 回答日時： 2017/02/13 19:09

同じ解答があるのかな？重複がありましたら、ごめんなさい。

これって、月数の計算ですよね。
B1:
=MOD(A1,12)+1
C1:
=MOD(B1,12)+1

この回答へのお礼

月の計算です。できました！ありがとうございます。

お礼日時：2017/02/13 19:33

No.8 回答者： tom04 回答日時： 2017/02/13 20:37

No.4です。

＞出来ればそれぞれ解説してもらえれば嬉しいです
というコトですので・・・
①　=IF(MOD($A1+COLUMN(A1),12)=0,12,MOD($A1+COLUMN(A1),12))
は
A1セルの数値に列番号（1・２・・・）を足し算するのですが、
その値を12で割ったあまりが「0」の場合は「12」を表示、それ以外は12で割ったあまりを表示！
という数式です。

②　=MONTH(DATE(2017,$A1+COLUMN(A1),1))
は
今年のA列数値の月のシリアル値とし、単に「月」の数値を表示させているだけです。
西暦年は何年でも良いと思いますが、とりあえず今年の「年」としています。
＞+COLUMN(A1)　で右へフィル＆コピーするたびに月の数値を「1」ずつプラスしています。

※　ただNo.6さんやNo.7さんの回答の方が
簡潔で判りやすいのではないでしょうか。m(_ _)m

No.7 回答者： yuji3690 回答日時： 2017/02/13 20:06

B1=A1+1-IF(A1=12,12,0)

C1=B1をコピー
A1の数字が1～12の場合のみです。

もしくは
=A1+COLUMN()-COLUMN(A1)-IF(A1+COLUMN()-COLUMN(A1)>12,12,0)

上のは単純なので分かると思いますが、左のセルに1加え、左のセルが12の場合には12引く。という式です。

下はその変形で、A1よりいくつ横にあるかをA1に加え、その値が12を超えていれば12を引く。としています。
書いてみたものの、上側で十分ですね。

No.5 回答者： GooUserラック 回答日時： 2017/02/13 18:39

何人かの方が確認されているのですがなぜ回答しないのでしょうか？

「１２と入力→１　２と反映」にどういう仕組みでなるのでしょうか？

・１２進法で処理するのでしょうか？
Ｂ１セルに「=MOD(A1+1,12)」
Ｃ１セルに「=MOD(A1+2,12)」

この回答へのお礼

月数計算です。ありがとうございます。
１１と入力すると０と１になります。

お礼日時：2017/02/13 19:38

No.4 回答者： tom04 回答日時： 2017/02/13 18:16

こんばんは！

B1セルに
=IF(MOD($A1+COLUMN(A1),12)=0,12,MOD($A1+COLUMN(A1),12))
または
=MONTH(DATE(2017,$A1+COLUMN(A1),1))
として、フィルハンドルで右へコピー！

こんな感じではどうでしょうか？m(_ _)m

この回答へのお礼

両方とも出来ました！ありがとうございます。
出来ればそれぞれ解説してもらえれば嬉しいです。

お礼日時：2017/02/13 19:30

No.3 回答者： ROKABAURA 回答日時： 2017/02/13 17:38

B1＝MOD(A1,12)+1

C1＝MOD(A1,12)+2

の間違いだな。
時間の表示かな？

この回答へのお礼

ありがとうございます。それだと11でC1が１３と出ます。改善できれば助かります。

お礼日時：2017/02/13 17:48

No.2 回答者： tatsu99 回答日時： 2017/02/13 17:29

A1に入力された数値に対して

B1、C1に出力してほしい結果を文章で提示していただけますでしょうか。

この回答へのお礼

言葉足らずすみません。

A1に１２と入力

A1 【12】B1 【1】C1【２】

A1に１と入力

A1【１】B1【２】C1【３】

このようなイメージです。
よろしくお願いいたします。

お礼日時：2017/02/13 17:33

No.1 回答者： 銀鱗 回答日時： 2017/02/13 17:15

B1＝MOD(A1-1,11)+2

C1＝MOD(B1-1,11)+2

この回答へのお礼

早速のご回答ありがとうございます。
１２だと２　３となります。

お礼日時：2017/02/13 17:25