エクセルで毎月第2週日の水曜日に〇が表示される 関数の組み合わせを教えてくれませんか？ 毎週水曜日な

エクセルで毎月第2週日の水曜日に〇が表示される
関数の組み合わせを教えてくれませんか？
毎週水曜日なら作れますが月1度のみ表示させる関数の組み合わせが分かりませんでした

No.6 ベストアンサー 回答者： goomania 回答日時： 2020/11/04 11:45

No.5です。

申し訳ありません。毎月二週目の水曜日と毎月第二水曜日を読み違えていました。
一般にその日が当月X週目〈本件では二週目〉の○曜日〈本件では水曜日〉かを判定するには、
○曜日であることに加えて、
(その日の曜日がその月何回目の出現か)+(月初日が○曜日より後の曜日〈本件では木曜日～土曜日〉なら1それ以外なら0)=X
という条件を満たす必要があります。本件の場合Xは2です。
これを数式にしたものが
=IF((WEEKDAY(A2)=4)*((ROUNDUP(DAY(A2)/7,0)+(WEEKDAY(EOMONTH(A2,-1)+1)>4)=2)),"○","")
となります。
ここで
WEEKDAY(A2)=4 は水曜日であることの判定
ROUNDUP(DAY(A2)/7,0 はその日の曜日がその月何回目の出現かのカウント
WEEKDAY(EOMONTH(A2,-1)+1)>4 は月初日が水曜日より後の曜日〈木曜日～土曜日〉なら1それ以外なら0
を意味します。
添付画像を参照してください。

この回答へのお礼

非常に分かりやすい説明で助かりました！
ありがとうございます

お礼日時：2020/11/18 11:43

No.7 回答者： goomania 回答日時： 2020/11/04 11:47

No.6です。

度々すいません。画像添付もれでした。
添付します。

No.5 回答者： goomania 回答日時： 2020/11/02 15:38

その日が○曜日である場合、その月の何回目の○曜日かを計算するためには

ROUNDUP(DAY(日付)/7,0)
という数式で算出できます。
したがって、第二水曜日を判定するためには、
水曜日であり、かつ、ROUNDUP(DAY(日付)/7,0) = 2 を満たせばよいことになります。
添付画像のようにA列・B列に日付・曜日があり、C列に第二水曜日を判定して○を表示するとすれば、
C2に
=IF((WEEKDAY(A2)=4)*(ROUNDUP(DAY(A2)/7,0)=2),"○","")
という数式を記述し、下方向にオートフィルでコピーすればよいと思います。

No.4 回答者： fujillin 回答日時： 2020/11/02 08:39

こんにちは。

すでに回答はでていますが、別案として・・・

A1セルに日付があるとして、〇を表示したいセルに

=IF((WEEKDAY(A1)=4)*(DAY(A1)>4)*(DAY(A1)<12),"〇","")

No.3 回答者： InspireTheBeauty 回答日時： 2020/11/02 01:20

No1 ですが、式を間違えました。

B2 に入力する式は以下の式です。
=IF(AND((WEEKNUM(A2)-WEEKNUM(DATE(YEAR(A2), MONTH(A2),1))+1)=2, WEEKDAY(A2)=4), "〇", "")


先の回答は、A1 からずっと日付が A列にならんでいるときの B1 の式でした。

No.2 回答者： Moryouyou 回答日時： 2020/11/02 01:09

どんなイメージで〇をするのか、

イメージが湧きませんが…

weeknum関数と
weekday関数を使います。

weeknum関数はその年の
第何週かが分かるので、
その月の1日を何週目かを求め
当日を引き算して+1して、
2になれば、第2週ということです。

それに加えて、
weekday関数で4になる日が、
第2週の水曜日のということに
なります。

添付に例を示します。

IF(AND(WEEKNUM(A7)-WEEKNUM("2020/11/1")+1=2,WEEKDAY(A7)=4),"〇","×")

No.1 回答者： InspireTheBeauty 回答日時： 2020/11/02 00:43

A 列に A2 から日付が下へずっと並んでいるとして、B 列の同じ行に第二週目の水曜日にだけ〇をするなら、

B2 に下の数式を入力して
=IF(AND((WEEKNUM(A1)-WEEKNUM(DATE(YEAR(A1), MONTH(A1),1))+1)=2, WEEKDAY(A1)=4), "〇", "")
下方向にコピー。