詳しい人求む！

Bookを閉じて保存した時のみ実行する

解決済

質問者：まさまちゃ
質問日時：2022/03/18 18:00
回答数：3件

Bookを閉じて「保存した時のみ」メールを送信するマクロです。
--------------------------------------------
Private Sub Workbook_AfterSave(ByVal Success As Boolean)
On Error GoTo ErrorHandler
Dim objOutlook As Outlook.Application
Dim objMail As Outlook.MailItem
Set objOutlook = New Outlook.Application
Set objMail = objOutlook.CreateItem(olMailItem)
With objMail
.To = "test@"
.CC = ""
.BCC = ""
.Subject = "【テスト】自動送信"
.Body = "このメールは自動テストメールです"
.BodyFormat = olFormatPlain
End With
objMail.Send
GoTo Finally
ErrorHandler:
MsgBox "メールの送信に失敗しました", vbOKOnly + vbCritical
Finally:
Set objOutlook = Nothing
End Sub
--------------------------------------------
AfterSaveではちょこちょこ上書き保存でも実行してしまうので
最後に保存して閉じた時だけ実行出来るようにしたいと思っています。
ご教授お願いします。

通報する

この質問への回答は締め切られました。

質問の本文を隠す

回答 (3件)

ベストアンサー優先
最新から表示
回答順に表示

No.3ベストアンサー

回答者：よろずやkinchan
回答日時：2022/03/18 21:03

Option Explicit

Private Saved As Boolean

Private Sub Workbook_AfterSave(ByVal Success As Boolean)
    Saved = True
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    If Not Saved Then Exit Sub
    On Error GoTo ErrorHandler
    Dim objOutlook As Outlook.Application
    Set objOutlook = New Outlook.Application
    With objOutlook.CreateItem(olMailItem)
        .To = "test@"
        .CC = ""
        .BCC = ""
        .Subject = "【テスト】自動送信"
        .Body = "このメールは自動テストメールです"
        .BodyFormat = olFormatPlain
        .Send
    End With
Finally:
    Set objOutlook = Nothing
    Exit Sub
ErrorHandler:
    MsgBox "メールの送信に失敗しました", vbOKOnly + vbCritical
    Resume Finally
End Sub