Excel VBA 定義されたプロージャ名、関数名の取得

次のようなVBAのコードをご指南ください。
実行すると、アクティブブックのモジュール内で定義されたサブプロージャ名や関数名を、種類とそれが定義されたモジュール名を併記する形で、メッセージボックスで一覧表示するマクロ。

実行結果のイメージ
Sheet1 (＊＊＊＊)　プロージャー　procA()
Sheet1 (＊＊＊＊) 　プロージャー　procB()
ThisWorkbook　イベントプロージャー　workbook_open()
標準モジュール　プロージャー　test()
標準モジュール　関数　func(hikisuA As Long, hikusuB As String)

他者がつくったマクロファイルが複雑で、モジュールがたくさんあります。どのモジュールにマクロが定義されているか、VBEを開いて１つ１つモジュールをダブルクリックして調べるのが面倒です。情報を得るのが目的なので、実行結果のイメージに深いこだわりはありません。詳しい方、よろしくお願いします。

No.1 ベストアンサー 回答者： fujillin 回答日時： 2024/04/07 14:22

こんにちは

モジュールからプロシージャを抜き出す簡単な方法をざっと探してみましたが、見つからなかったので、以下は1行ずつ調べるというローテクな方法です。
事前に設定した（＝変数pre）に該当する Sub、Function を抜き出しますので、ClassやDeclare、Proparty、Enumなどは無視します。

＞メッセージボックスで一覧表示するマクロ。
対象が多い場合に、メッセージボックス表示ではあんまりと思いますので、ActiveSheetのA、B列に一覧を列挙するようにしてあります。
また、モジュール名はオブジェクト名になりますので、シートの表示名とは異なる可能性があります。
（シート名表示の方が良ければ、読み替えを追加してください）

以下、ご参考までに。

Sub Q13781167()
Dim i As Long, j As Long
Dim rg As Range, s As String
Dim pre, t, m, p

pre = Split("Sub ,Private Sub ,Public Sub ,Function ,Private Function ,Public Function ", ",")
Columns("A:B").ClearContents
Set rg = Range("A1:B1")
rg.Value = Array("[Module Name]", "[Proc Name]")

For Each t In Array(100, 1, 3)
For Each m In ActiveWorkbook.VBProject.vbcomponents
If m.Type = t Then
If rg(1).Value <> "" Then Set rg = rg.Offset(1)
rg(1).Value = m.Name
For j = 1 To m.codemodule.CountOfLines
s = m.codemodule.Lines(j, 1)
For Each p In pre
If Left(s, Len(p)) = p Then rg(2).Value = s: Set rg = rg.Offset(1): Exit For
Next p
Next j
End If
Next m
Next t
End Sub

この回答へのお礼

教えてくださりありがとうございます。教えていただいたコード、私の環境でも実行でき期待した結果が得られました。回答をいただいて、コードの中身を理解するのに時間がかかり、お礼がたいへん遅くなりましたが、とても参考になりました。

m.codemodule.CountOfLinesやs = m.codemodule.Lines(j, 1)
などのcodemoduleは一度も目にしたことがありませんでした。
それから、選択範囲rgのOffsetの利用の仕方が秀逸です。Arrayの使い方も参考になりました。preをSplitで定義することで、多条件の場合分けを可能にしている点も参考になりました。

たくさんの工夫が詰め込まれたコードを教えていただきました。どこまで使いこなせるかわかりませんが、他のコードにも利用できるように勉強していきたいと思います。ありがとうございました。

お礼日時：2024/04/13 06:15