エクセルで文字と数字が入っているセルを足すには

解決済

質問者：momotaroo
質問日時：2005/08/18 21:02
回答数：6件

エクセルで文字と数字が一緒に入っているセルの数字
だけを合計することはできるでしょうか?
例えば、休8のようなセルです。
よろしくお願いいたします

通報する

この質問への回答は締め切られました。

質問の本文を隠す

回答 (6件)

ベストアンサー優先
最新から表示
回答順に表示

No.3ベストアンサー

回答者： Wendy02
回答日時：2005/08/18 22:30

こんばんは。

もう少し、具体的な例がほしいですね。
ただ、基本的な使い方をもう少し考えたほうがよいです。数字は計算できますが、文字はカウントしかできません。

以下のようなテクニックで可能ですが、あまり標準的ではありません。

休
休1
休3
休6
休5
休2
休7

A8:
=SUM(IF(LEN(A1:A7)>1,SUBSTITUTE(A1:A7,"休","")*1,0))

配列数式ですから、一旦式を入力したら、F2を押して、『ShiftとCtrlを押しながらEnterキー』を押して、再確定してください。

後は、#1さんのご指摘のように、マクロ等で、数字を拾い出して計算するしかありません。

- 1
- 件

通報する

No.6

回答者： imogasi
回答日時：2005/08/19 20:58

A1に「休み4」（漢字は何文字でもよい、数字も何文字でもよい、数字は

後半にあるものとする）
とかあるとき（
（１）全角漢字と半角数字の組合せとする
B1に
=RIGHT(A1,LENB(JIS(A1))-LENB(A1))
を入れると4となります。それらをB列で足せばよい。
------
（２）数字が全角数字なら
=VALUE(RIGHT(A3,LENB(A3)-LENB(ASC(A3))))
です。英字記号などがないとの仮定です。

- 2
- 件

通報する

No.5

回答者： maruru01
回答日時：2005/08/19 13:45

こんにちは。

maruru01です。

文字が"休"だけの場合は、

=SUMPRODUCT(--SUBSTITUTE("0"&A1:A5,"休",))

"休"だけではなく、"出"などいろいろな文字（ただし1文字）があって、全部足す場合は、

=SUMPRODUCT(--("0"&REPLACE(A1:A5,1,1,)))

いろいろな文字があるが、"休"だけを足す場合は、

=SUMPRODUCT(("0"&REPLACE(A1:A5,1,1,))*ISNUMBER(FIND("休",A1:A5)))

範囲は適宜変更して下さい。

- 5
- 件

通報する

No.4

回答者： ta123
回答日時：2005/08/18 22:33

以下の配列数式でできそうです。

=SUM(IF(LEN(A1:A10)>0,VALUE(RIGHT(A1:A10,1)),0))

※配列数式：上記数式をCtrl+Shift+Enterで確定する。
　（詳しくはExcelヘルプを参照願います。）

1.合計対象セルがA1～A10
2.[文字＋数値]の書式は最後の1文字が数字
3.合計対象セルには空白セルも含む

- 3
- 件

通報する

No.2

回答者： noname#12834
回答日時：2005/08/18 22:29

ひとつのセルに文字と数値が入っている場合文字列として認識されるので無理だと思います。

　　A　 B　C
１　休　8　SUM(B1:B2)
２休　8
３ SUM(B1:B2)　　のようにセルを分けて入力して
A列とB列の幅を狭くしてセルA3とB3（C1とC2）を結合すれば見た目はA,B列の中心（1,2行の中心）に合計があるようになると思います。

- 0
- 件

通報する

No.1

回答者： TinyPine
回答日時：2005/08/18 22:11

文字の加算は出来ません。

文字が入っているセルは文字と認識されます。どうしても加算したければマクロを使用して文字部分と数字部分を分離させて数字部分を加算すると言う事は可能です。

又、例の"休"が固定であれば、書式のユーザー定義を使用して"休"0の定義を指定すればデーターとしては例えば123と成っていても、表示上は"休123"と成り、このデーターはSUM等で加算出来ます。

"休"以外にも文字があるなら、複数のユーザー定義を行い、コピーアンドペーストすればデーター部分の合計を取る事は可能です。