エクセルのマクロについて教えてください。

Question

エクセルのマクロについて教えてください。
マクロを実行して、テキストファイルを作成、そのテキストファイル名及び
テキストファイルの内容をマクロを設定しているシートとセル値を設定できますでしょうか。
私の希望が叶うようであれば、詳しいい内容を補足させていただきます。
よろしくお願いいたします。

tatsumaru77 · Accepted Answer

以下のマクロを標準モジュールに登録してください。

Option Explicit

Public Sub テキストファイル作成()
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Dim fname As String
    Dim result As Boolean
    Dim err_str As String
    Dim atesaki As String
    Dim tanto As String
    Dim text_path As String
    Set ws1 = Worksheets("青紙表")
    Set ws2 = Worksheets("審査")
    fname = ws1.Range("CK1").Value
    If fname = "" Then
        MsgBox ("ファイル名が空白です")
        Exit Sub
    End If
    result = CheckFileName(fname, err_str)
    If result = False Then
        MsgBox ("ファイル名として使用できない文字[" & err_str & "]があります")
        Exit Sub
    End If
    atesaki = ws2.Range("B1").Value
    If atesaki = "" Then
        MsgBox ("宛先が空白です")
        Exit Sub
    End If
    tanto = ws2.Range("G13").Value
    If tanto = "" Then
        MsgBox ("担当者が空白です")
        Exit Sub
    End If
    text_path = ThisWorkbook.Path & "\" & fname & ".txt"
    Open text_path For Output As #1
    '宛先
    Print #1, tanto
    '固定文字
    Dim fstr1 As String
    Dim fstr2 As String
    Dim fstr3 As String
    fstr1 = "お世話になっております、回答書を確認いたしましたが、下記の内容を再度ご確認ください。"
    fstr2 = "修正図書をWebにアップをお願いします。"
    fstr3 = "以上です。 よろしくお願いします。"
    Print #1, fstr1
    Print #1, fstr2
    Print #1, fstr3
    '担当者
    Dim vstr1 As String
    vstr1 = "担当者：" & tanto
    Print #1, vstr1
    Close #1
End Sub
'ファイル名として使用できない文字が含まれているかチェックする
Public Function CheckFileName(ByVal fname As String, ByRef err_str As String) As Boolean
    Dim estrs As Variant
    Dim i As Long
    Dim estars As Variant
    CheckFileName = False
    estars = Array("\", "/", ":", "*", "?", "<", ">", "|", """")
    For i = 0 To UBound(estars)
        If InStr(fname, estars(i)) > 0 Then
           err_str = estars(i)
           Exit Function
        End If
    Next
    CheckFileName = True
End Function

tatsumaru77 · Answer

No3です。補足ありがとうございました。

１．文字コードはシフトJISと解釈しました。
２．下記の件
＞上の文字例と下の文字例の間のこの部分に、物件ごとの文字を自由に書き込みをして
＞一つのテキストファイルを完成させたいのですが、可能でしょうか？

自由に書き込みをするのは、テキストファイルを作成後、メモ帳などで、
作業者が手作業で行うということでしょうか。（マクロは関知しない）
それであれば、問題ないです。

３．出力ファイル名ですが、
出力ファイル名が、「サンプル.txt」の場合、

シート：青紙表のCK1セルの内容は、
①サンプル
②サンプル.txt
のどちらでしょうか。
つまり、CK1セルは、拡張子を含めた名前で定義するのでしょうか。
それとも、拡張子を除いた名前を登録するのでしょうか。
という質問です。

tatsumaru77 · Answer

以下の内容で間違いないでしょうか。①②がセル内の文字で、以外は固定文字です。
-----------------------------------------------------
①⏎
お世話になっております、回答書を確認いたしましたが、下記の内容を再度ご確認ください。⏎
修正図書をWebにアップをお願いします。⏎
以上です。 よろしくお願いします。⏎
担当者：②⏎
-----------------------------------------------------
①（宛先）　シート：審査　のB1セルの内容
②（担当者名）　シート：審査　のG13セルの内容
出力ファイル名：シート：青紙表のCK1セルの内容
⏎は、テキストファイルへ出力した時の改行コードの位置になります。
テキストファイルの文字コードはシフトJISで間違いないでしょうか。

「下記の内容を再度ご確認ください。」の下記の内容についてですが、
下記の内容に該当するものが見当たりません。
下記の内容とは何のことだろう、と宛先の方は思ってしまうと思いますが、それは杞憂でしょうか。
杞憂であれば、問題ありません。無視してください。

shut0325 · Answer

shut0325です。

ほぼテキスト操作ですね。

まずは、実際の体裁通りの文を作られることからされた方が良いかと思います。

その上で、情報がやや足りないように思います。

まず、1行目は宛先とのことですが、様　や　御中　などの付与はされなくてよいのでしょうか？

次に3行目にあたると思われるところの、No.となっている部分ですが、No.＋該当図書番号　ではないでしょうか？　その場合、図書番号が書かれているセルはどこでしょうか？

その上で、「物件により分岐（変わる）」ということですが、その分岐条件は何の値で判断するのでしょうか？

shut0325 · Answer

はい。できますよ。

やり方はいくつかあります。私はVBSで書く場合もあり、FileSystemObjectを利用して実現しています。

下記ページをを参照/応用されるとよいかもしれません。

https://excel-vba.work/2022/02/12/vba%E3%83%86%E3%82%AD%E3%82%B9%E3%83%88%E3%83%95%E3%82%A1%E3%82%A4%E3%83%AB%E3%82%92%E6%96%B0%E8%A6%8F%E4%BD%9C%E6%88%90%E3%81%99%E3%82%8B/

エクセルのマクロについて教えてください。

以下のマクロを標準モジュールに登録してください。

No3です。

以下の内容で間違いないでしょうか。

shut0325です。

はい。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング