○秒後にフレーム移動

たとえば３フレーム目で静止をして20秒たったら、４フレーム目へ移動、ということがしたいのですが、どのようにスクリプトをかけばいいのでしょうか？

FLASH5です。

No.1 ベストアンサー 回答者： DPE 回答日時： 2004/03/01 17:21

Flash MX なら、○秒ごとに指定の関数を呼び出す setInterval という関数が使えるところですが、Flash 5 でタイマーの処理をするとなると、少々工夫が必要です。

Flash Player 4 以降から使える getTimer を利用して、このようにしてみてはいかがでしょう。

getTimer はムービーが再生されてからの時間をミリ秒で返します。
変数を２つ用意します。その１つ（仮に before_time とします）に、前のフレームでの getTimer の戻り値を保存しておきます。
すると、今のフレームでの getTimer の戻り値との差で、前のフレームからどのくらい時間が経過したかを知ることができるようになります。
この経過時間の差を、もう１つの変数（仮に lag とします）に蓄積していきます。
getTimer の単位はミリ秒ですので、20秒＝20000ミリ秒となります。lag の値が 20000 以上であれば、20秒経過したと見なすことができます。フレームレートの都合上、数ミリ秒の誤差が生じますが、ご容赦ください。
フレームごとの経過時間は、onClipEvent の enterFrame イベントハンドラを利用して計ります。ムービークリップであれば何でもいいのですが、専用のムービークリップを１つ用意（絵は適当でも、なくても構いません）し、これを非表示にしてステージに置いておくといいでしょう。

例えば、timer というムービークリップがあるとします。フレーム３にキーフレームを設定し、 timer をステージのどこかに置きます。アルファを０にするか、onClipEvent の load イベントハンドラを使ってロード直後に _visible プロパティを false にし、非表示にします。
このムービークリップで、時間の計測とメインのタイムラインのフレーム移動の処理を一括して行います。
なお、フレーム４に移動すれば timer の役割は終わりですので、フレーム４以降はステージに置いておく必要はありません。メインのアニメとは別に、専用のレイヤーを作って管理すると、分かりやすくなるかと思います。
timer に設定するスクリプトは、大体、このような感じになります。
（↓　このスクリプトをコピーして利用する場合は、各行の行頭に入っている全角のスペースを、全て半角のスペースかタブに置き換えてください。このまま使うとシンタックスエラーになります）


　//初期設定
　onClipEvent( load )
　{
　　//前のフレームでの経過時間を保存する変数
　　//初期値は現時点での経過時間
　　before_time = getTimer();

　　//前のフレームとの経過時間の差を管理する変数の初期化
　　lag = 0;

　　//自分自身を不可視にする
　　this._visible = false;
　}


　//20秒後にフレーム４へジャンプ
　onClipEvent( enterFrame )
　{
　　var now_time;

　　//現フレームでの経過時間を計測
　　now_time = getTimer();

　　//前フレームとの経過時間の差を蓄積
　　lag += now_time - before_time;

　　//現フレームの経過時間を保存
　　before_time = now_time;


　　//蓄積された差が20000以上であれば20秒経ったと見なし、
　　//メインのタイムラインを動かす
　　if ( lag >= 20000 )
　　{
　　　_root.gotoAndPlay( 4 );
　　}
　}


この方法をもう少し工夫すると、○秒ごとに一定の処理を行う、MX で追加された setInterval と同様の処理にもなります。
以前、５秒ごとに処理を行うには・・・という質問で、やはり getTimer を使ったスクリプトを紹介したことがあります。実は、基本的な考え方は全く同じですので、よろしかったら覗いてみて下さい。

参考URL：http://www.okweb.ne.jp/kotaeru.php3?q=666930

この回答へのお礼

回答ありがとうございます。
無事にgetTimerでやりたいことができました。
ありがとうございました。

お礼日時：2004/03/02 09:30