findstrのerrorlevel

少し前に、
pingが通るか否かではerrolevelが立たないというので、
findstrを教わりました。

ただ、findstrだけを動かしたとき(test2)には正しく動くのですが、
前に別のロジックがある(test1)と必ずerrorlevelが「0」になるみたいです。
原因を教えて下さい。

test1は以下のとおりです。
echo off
ping 192.168.0.9 > obj8
for %%i in (obj8) do (if %%~zi==0 (
echo ping-kekka-nashi
) else (
ping 192.168.0.9 | findstr TTL
if %errorlevel%==0 (
echo ping kekka-ari ok
) else (
echo ping-kekka-ari ng
)))


test2は以下のとおりです。
@echo off
ping 192.168.0.9 | findstr TTL
if %errorlevel%==0 (
echo ping-kekka ok
) else (
echo ping kekka ng
)

※実際には、192.168.0.9は存在しないので、pingは通りません。
宜しくお願いします。

No.1 ベストアンサー 回答者： artoo 回答日時： 2021/01/15 23:12

%による環境変数展開は、命令実行前に展開されてから実行されます。

つまり、test1のfor文は、for文実行の直前でERRORLEVELが0の場合、

for %%i in (obj8) do (if %%~zi==0 (
echo ping-kekka-nashi
) else (
ping 192.168.0.9 | findstr TTL
if 0==0 (
echo ping kekka-ari ok
) else (
echo ping-kekka-ari ng
)))

と書き換わってから、forの実行が始まります。
言い換えると、for の開始前と開始後で値が変わる変数の参照を%で行うことは出来ません。なので、%を使わないif文を書きます。

if errorlevel 1 ・・・・ errorlevel が1以上なら～～
if not errorlevel 1 ・・・上記の否定、つまり、errorlevelが0なら～～

↓
echo off
ping 192.168.0.9 > obj8
for %%i in (obj8) do (if %%~zi==0 (
echo ping-kekka-nashi
) else (
ping 192.168.0.9 | findstr TTL
if not errorlevel 1 (
echo ping kekka-ari ok
) else (
echo ping-kekka-ari ng
)))

この回答へのお礼

早速有り難うございました。
ご説明、良く分かりました。
そんなこととはつゆ知らず、のたうち回っていました。
スッキリしました。

勿論訂正して実行、スンナリです。
お世話になりました。
大感謝です。

お礼日時：2021/01/16 06:52