読み込んだ画像のサイズ調整

PHPでデータベースの内容を読み込み、それをActionScriptで使用するFlashを作っています。

PHPで、データベースの内容（画像のパス）を読み込み、
ActionScriptで表示させるところまでできたのですが、
表示サイズを変更するところができません。

作ったのは以下のようなプログラムです。
------------------------------------------------------
myVars = new LoadVars();
myVars.onLoad = function(){
img1.loadMovie(this.img1);
}
myVars.load("http://127.0.0.1/gazo1-1.php");
------------------------------------------------------

gazo1-1.phpの実行結果は
------------------------------------------------------
img1=FUKU1/1longcardi.jpg
------------------------------------------------------
です。

上記のプログラムで、変数名img1のムービークリップにFUKU1/1longcardi.jpgを表示するまではできたのですが、
表示したいサイズに合わせることができません。

MovieClipLoaderを使って、読み込み終了してからサイズを変えるという方法もためしたのですが、使い方が間違っているのか
うまくいきませんでした。
以下が試したプログラムです。


------------------------------------------------------
myVars = new LoadVars();
myVars.onLoad = function(){
　　　　　
MoveiClipLoader.loadClip("img1",this.img1);
onLoadComplete=function(img1){
img1._width=157.9;
img1._height=205;
}
}
myVars.load("http://127.0.0.1/gazo1-1.php");
------------------------------------------------------


回答お願いいたします。

No.1 ベストアンサー 回答者： sassakun 回答日時： 2007/01/15 19:37

MoveiClipLoader（正：MovieClipLoader） の綴りも違っていますし，

スクリプトの文章も大変なことになっていますよ。

次のようにしてみてください↓。

------------------------------------------
myVars = new LoadVars();
// myVars に変数ロード完了時の処理
myVars.onLoad = function(Seikou) {
// 成功したら
if (Seikou) {
// ユーザー定義関数 loadJPEG() の実行
loadJPEG();
} else {
trace("変数のロード失敗");
}
};
myVars.load("Ｈttp://127.0.0.1/gazo1-1.php");
//
// ユーザー定義関数 loadJPEG() の定義
function loadJPEG() {
// myMCL という MovieClipLoaderインスタンスの生成
myMCL = new MovieClipLoader();
// myListener というリスナーオブジェクト生成
myListener = new Object();
// ロード完了時（ファイル表示時）の処理
myListener.onLoadInit = function(targetMC) {
targetMC._width = 157.9;
targetMC._height = 205;
};
// イベントリスナーの登録
myMCL.addListener(myListener);
// 外部SWFファイル"test.swf"をインスタンスmy_mcにロード
myMCL.loadClip(myVars.img1, img1);
}
-------------------------------------------

LoadVars の onLoad 内に，
MoveiClipLoaderクラスのメソッドが入ると見かけ上非常にややこしくなるので，
LoadVars の onLoad の外に，
MoveiClipLoaderクラスのメソッドを持って行くために，
ユーザー定義関数 loadJPEG() を定義して分離しました。


PHPを作成してまでの検証はしていません（できません）。

しかし一応，
SWF ファイルと同じフォルダに，
中味はただの
----------------------
img1=mygazo1.jpg
----------------------
というデータを書いたファイル名「gazo1-1.php」というのテキストファイルを用意し，
「mygazo1.jpg」というJPEGも用意して検証した結果，うまく行きましたよ。


上のスクリプトを使用される場合は，
myVars.load("Ｈttp://127.0.0.1/gazo1-1.php");
このURLの頭の Ｈ を半角小文字の h に変えてください。
http だと勝手にリンクがかかってしまって，
妙な見えない文字がアクションパネルにコピペされ，うまく動かない場合があります。
ですから自働リンクがかからないようにしてあるのです。
このコミュニティの困った仕様の問題です。

この回答へのお礼

お返事遅れてすみません。
綴りまで間違ってましたか（＾＾；）
でも、書いてある通りにしたら、できました！！
本当にありがとうございました！！（＾▽＾）
助かりました。

お礼日時：2007/01/18 14:19