取得した時間の表示について。

現在デジタル時計を表示しています。が
この表示の形を変更したいのです。

//以下スクリプト

var now:Date;
var h:Number, m:Number, s:Number,l:Number,d:Number,o:Number,p:Number;
this.onEnterFrame = function() {
now = new Date();
d = now.getFullYear();
o = now.getUTCMonth()+1;
p = now.getUTCDate();
h = now.getHours();
m = now.getMinutes();
s = now.getSeconds();
l = now.getMilliseconds();
date.text = d;
mon.text =o;
day.text =p;
Hours.text = h;
Minute.text = m;
Seconds.text = s;
mini.text = l;

}

//

このスクリプトでは現在、静止テキスト"/" 、":"を挟み

2006/12/ 2/ 18: 5:974

のように表示されます。
この時計の表示を

06/12/02/18:05:97

のように表示したい（すべてのデータを二桁に）のですが
うまくいきません。
何か良い方法がないか探しております
よろしくお願いします。

No.1 ベストアンサー 回答者： sassakun 回答日時： 2006/12/02 20:02

他のサイト(JavaScript や ActionScript系サイト)などのように普通に考えると，

こう↓ではないでしょうか。
-------------------------------------------
var now:Date;
var h:Number, m:Number, s:Number, l:Number, d:Number, o:Number, p:Number;
this.onEnterFrame = function() {
now = new Date();
d = now.getFullYear();
o = now.getUTCMonth()+1;
p = now.getUTCDate();
h = now.getHours();
m = now.getMinutes();
s = now.getSeconds();
l = now.getMilliseconds();
//
// ↓ココから下を変更↓
date.text = d.toString().substr(2, 2);
if (o<=9) {
mon.text = "0"+o;
} else {
mon.text = o;
}
if (p<=9) {
day.text = "0"+p;
} else {
day.text = p;
}
if (h<=9) {
Hours.text = "0"+h;
} else {
Hours.text = h;
}
if (m<=9) {
Minute.text = "0"+m;
} else {
Minute.text = m;
}
if (s<=9) {
Seconds.text = "0"+s;
} else {
Seconds.text = s;
}
// 結局コレ↓はどうしたいのかわかりません。
mini.text = l;
};
-------------------------------------------

上のような感じのはよく見ます。
得られた数が 9 以下であれば，前に "0" を付けるというものです。
すごく一般的で，私は今のところこのパターンしか見たことがありません。

もちろん，
変数名やテキストのインスタンス名に，
o,p,h,s,m…　と付けるのではなく，
date0,date1,date2,date3…　などと連番で付けておくと，
長い長い if 文は， for文で短くできますが，
人間が見るとわかりにくくなるので，これはどちらでも良いと思います。


しかし！
今回のご質問でもっと単純な考え方を閃きました。
-------------------------------------------
var now:Date;
var h:Number, m:Number, s:Number, l:Number, d:Number, o:Number, p:Number;
this.onEnterFrame = function() {
now = new Date();
d = now.getFullYear();
o = now.getUTCMonth()+1;
p = now.getUTCDate();
h = now.getHours();
m = now.getMinutes();
s = now.getSeconds();
l = now.getMilliseconds();
//
// ↓ココから下を変更↓
date.text = d.toString().substr(-2, 2);
mon.text = ("0"+o).substr(-2, 2);
day.text = ("0"+p).substr(-2, 2);
Hours.text = ("0"+h).substr(-2, 2);
Minute.text = ("0"+m).substr(-2, 2);
Seconds.text = ("0"+s).substr(-2, 2);
// 結局コレ↓はどうしたいのかわかりません。
mini.text = l;
};
-------------------------------------------

こうすれば，鬱陶しい if文が不要になります。
ちょっとした発明かもしれません。
（発明でないかもしれません。よくわかりません。）

1桁でも2桁でも何でも良いから，
強制的に前に "0" を付けて，
下２桁から２文字を取ってくるという方法です。
.substr(-2, 2);
-2 は 最後から２文字目，2はそこから２文字 という意味です。
これで良いのではないでしょうか。

他で見たことがないので，
どこかに落ち度があるかもしれませんが，
おそらくこれで行けますよ。


※　// 結局コレ↓はどうしたいのかわかりません。
　　 mini.text = l;
　　 は，どうしたいのかよくわかりません。
　　 上のことから考えてみてください。

この回答へのお礼

まずmini.text = l;は
getmillisecondsでミリ秒を取得していた名残です。
うっかり削除するのを忘れていました。混乱させてしまい申し訳ありません。
そして肝心のスクリプトなのですがバッチリでした。
一桁の情報は一文字しか含んでいないという当たり前の事なのに
下二桁を得るというやり方は考えもしていなかったので
こんなにスッキリ書いておられる事に本当に驚いています。
本当に助かりました。ありがとうございました。

お礼日時：2006/12/03 00:04