【EXCEL】複数の条件でのカウント

EXCELで、複数（2つ）の条件でカウントしたいです。
下記のようなリストから、
「"関東・男"が○名」「"関東・女"が○名」・・・というように
カウントしたいのですが、どのような関数でできますか？
同じような質問がいくつもあるのは承知なのですが、
参考にしても答えが出せなかったので、質問させていただきました。
よろしくお願いいたします。


所在地　性別
関東　　男
関東　　男
関東　　女
関西　　男
関西　　女
関西　　女
関東　　女
関東　　男
関東　　女
関西　　男

No.4 ベストアンサー 回答者： mshr1962 回答日時： 2008/05/30 15:32

１．データのピボットテーブルで所在地と性別を列にして

性別をデータの個数として集計させる。

２．Excel2007であればCOUNTIFS関数を使用
=COUNTIFS(A:A,"関東",B:B,"男")

３．SUMPRODUCT関数を使用
=SUMORODUCT(($A$1:$A$100="関東")*($B$1:$B$100="男"))

４．配列数式を使用
=SUM(IF(($A$1:$A$100="関東")*($B$1:$B$100="男"),1))
としてCtrl+Shift+Enterで配列数式に変換

５．C列を作業列にして
C2=A2&B2
で下方にコピー
=COUNTIF(C:C,"関東男")

No.5 回答者： M851-C2351 回答日時： 2008/05/31 23:01

複雑な集計でないようでしたら、『オートフィルタ』を使ってメモ用紙にでも控えた方が、手っ取り早く集計出来ます。

例題で言うならば、
Ａ列は『関東』を選択、Ｂ列は『男』を選択すると、左下の欄外にデータ個数が表示されます。もし、表示されないようでしたら、Ａ列なりＢ列を選択し、下の欄外で右クリックすると『合計』『平均』などを選択する画面が現れます。その上の方に『データの個数』がありますのでクリックしてください。右下の欄外に『データの個数＝○個』と現れるはずです。

本格的に集計する必要があるようでしたら、ちょっと取っ付き難いですが『DCOUNT』関数を使えば、集計する条件は事実上無制限に設定出来ます。説明が複雑になりますので、もしご興味があるようでしたら、お知らせ下さい。

No.3 回答者： Turbo415 回答日時： 2008/05/30 13:47

いろいろやり方はあるでしょけど。

出身地をA列、性別をB列として、　データが1行目から20行有るとします。
C列をワークとして使います。
C1に＝A1&B1と入れてC1セルに”関東男”と表示させます。その式を縦にコピーして各行のC列に出身地と性別のつながったデータを作りす。
そしてD1に件数を表示させるならD1に=countif(C1:C20,D2)とします。
その後D2に条件を入れると件数が出てきます。また、C列を非表示にすると間違えて式を消すこともないし、見た目もすっきりします。あとは、調べたい条件をD2に入れれば良いです。D2に関東男と入れればその条件の件数が出ます。もし関東だけの件数が出したければ関東*とすれば良いですし、男だけを出したければ*男と入れればいいです。出身地に北海道とか九州とかが加わってもできます。

こんなのでどうでしょう。

No.2 回答者： higekuman 回答日時： 2008/05/30 13:46

どのような工夫をしましたか？

作業用の列を作ってみましたか？
たとえば、C列に、A列が関東でB列が男だったら1、そうじゃなかったら0、という数式を書いて、その合計を求めれば、"関東・男"の人数はわかります。
その上で、作業列を作りたくない、というのであれば、SUMPRODUCT関数を使うという手もありますが、まずは作業列を作って求められるようじゃないと、SUMPRODUCT関数を使う上で必要になる想像力もないと思います。

No.1 回答者： shinkun0114 回答日時： 2008/05/30 13:40

　　 A　　 B

1 | 関東 | 男 |
2 | 関東 | 男 |
3 | 関東 | 女 |
4 | 関西 | 男 |
5 | 関西 | 女 |
6 | 関西 | 女 |
7 | 関東 | 女 |
8 | 関東 | 男 |
9 | 関東 | 女 |
10| 関西 | 男 |

こんな感じでデータが並んでいたとします。
たとえば、関東＋男の条件で抽出する式を考えてみます。使う関数はSUMPRODUCTです。
=SUMPRODUCT(($A$1:$A$10="関東")*($B$1:$B$10="男")*1)
A1～A10で関東のもの、B1～B10で男のものを抽出し、1をかけることで個数を集計しています。

*****
それぞの条件をカウントする場合は、下のように集計表を作り、
　　 A　　 B
12| 関東 | 男
13| 関東 | 女
14| 関西 | 男
15| 関西 | 女
となりのC列に集計の式を入れます。C12セルには
=SUMPRODUCT(($A$1:$A$10=A12)*($B$1:$B$10=B12)*1)
このような式が入ります。あとは下にコピーすれば、組み合わせ分の集計値が得られます。