現在のブックを閉じないで、マクロ抜きの（現在のブックの）コピーを作成したい

次のプログラムでコピーできるのですが、コピーされたSample1.xlsxを立ち上げると「ファイル形式と拡張子が一致していません」となってしまいます。
Sub Sample()
Application.DisplayAlerts = False
ActiveWorkbook.SaveCopyAs "C:\Sample1.xlsx"
Application.DisplayAlerts = True
End Sub

質問者からの補足コメント

• これだと現在開いているブックが閉じてしまいます。

  No.1の回答に寄せられた補足コメントです。 補足日時：2024/04/20 09:38

No.4 ベストアンサー 回答者： fujillin 回答日時： 2024/04/20 11:35

こんにちは

以下でもいけると思います。

Sub Sample()
Const p = "C:\Sample1.xlsx"

With CreateObject("Excel.Application")
.Application.DisplayAlerts = False
.Workbooks.Open(ThisWorkbook.FullName).SaveAs p, 51
.Workbooks(1).Close
.Quit
End With
End Sub

この回答へのお礼

希望のものができました。
皆様ありがとうございました。

お礼日時：2024/04/20 12:54

No.5 回答者： いんちょ 回答日時： 2024/04/20 19:19

No.3です。

やったことなかったのですが、Worksheets.Copyはシート指定しないと全シートがコピーされますね。ということで、

Worksheets.Copy
ActiveWorkbook.SaveCopyAs "C:\Sample1.xlsx"

でOKでした。

この回答へのお礼

再度ありがとうございます。でもやはりうまくいきませんでした。
No.4のプログラムは、瞬きしないし、入れ替わらないし、拡張子が不正にもならないし、警告も出ないし、何より短くて良かったので、そちらをBAにしました。

お礼日時：2024/04/22 11:35

No.3 回答者： いんちょ 回答日時： 2024/04/20 10:47

ワークシートはいくつもあるのでしょうか？一つだけならWorksheets.Copyでコピー先を指定しなければ新しいブックができるので、それをSaveAsで保存すればいいです。

他にシートがあるなら新しいブックに追加でコピーしてSaveAsすればいいです。

この回答へのお礼

ありがとうございました。

お礼日時：2024/04/20 12:55

No.2 回答者： Qchan1962 回答日時： 2024/04/20 10:20

力技なら

Dim bk As Workbook
Dim bkPath, bkName
ActiveWorkbook.Save
bkPath = ActiveWorkbook.Path
bkName = ActiveWorkbook.Name
Application.ScreenUpdating = False
Application.DisplayAlerts = False
ActiveWorkbook.SaveAs Filename:="C:\Sample1.xlsx", FileFormat:=51
Set bk = ActiveWorkbook
Workbooks.Open bkPath & "\" & bkName
bk.Close
Application.DisplayAlerts = True
Application.ScreenUpdating = True

この回答へのお礼

ありがとうございました。

お礼日時：2024/04/20 12:56

No.1 回答者： enunokokoro 回答日時： 2024/04/20 09:30

SaveCopyAsではなく、別名保存としてSaveAsを使います。

このとき、xlOpenXMLWorkbookを指定することでマクロなしで
保存ができます。
http://officetanaka.net/excel/vba/tips/tips214.htm

この回答へのお礼

ご提示のプログラムはやったことがありますが、実行すると、現在編集中のブックが新しくできたブックに入れ替わってしまいます。引き続き編集できるようにするにはどうすれば良いでしょうか。

お礼日時：2024/04/20 09:51