マクロで検索条件２つのデータを探してくるには

Question

かなり初心者の質問ですいません。

マクロで、エクセルのVLOOKUP関数のような事がやりたいのですが、
条件を２つ設定することはできるのでしょうか。

データは、

ファイル１　商品データA.xls
ファイル２　商品データB.xls
ファイル３　グループ分け分類.xls

とあり、まずはマクロで「商品データA」の下に「商品データB」を貼り付けます（ここまでは問題ありません）

このデータには「商品コード」と「区分」があります。
これに応じて、ファイル３の「グループ分け分類.xls」から
データを引っ張ってきたいのです。

（ファイル１・２の加工物にも、ファイル３にも
　「商品コード」と「区分」があります）

この場合のコードのやり方がわかりません。

imogasi · Accepted Answer

質問の表現の意味ががはっきりしない。
検索されるデータは商品データA.xlsのシート１と商品データB.xls
のシート１とか、なのか（シートまではっきり書くこと。または複数シート全体か。エクセルはシートのデータを直接的には扱うのだ。）
そしてシートのデータのフォーマットは同じなのか。
検索の場合は同じでなくてもよい場合があるが。
＞これに応じて、ファイル３の「グループ分け分類.xls」から
データを引っ張ってきたいのです。
これだとグループ分け分類.xlsが検索されるデータなのか？
「から」といえばそうも取れる。
むしろ、条件のようなものが「グループ分け分類.xls」にあるのでは無いのか？
簡単な実例でも挙げて表現しないと「、何を言っているか判りにくい。
ーー
マクロの記録コードの修正で対処できなかったのか。

_Kyle · Answer

今更ですが…。

まず、素朴に書く場合。
'=====↓　ココカラ　↓===============================================
Sub Sample()

　Dim mstSht As Worksheet
　Dim tgtSht As Worksheet
　Dim i　　　As Long
　Dim j　　　As Long
　
　Set mstSht = Workbooks("グループ分け分類.xls").Worksheets("Sheet1")
　Set tgtSht = Workbooks("結合データ.xls").Worksheets("Sheet1")
　
　'結合データの２行目から最終行まで回す
　For i = 2 To tgtSht.Cells(Rows.Count, "A").End(xlUp).Row
　　'グループ分け分類の２行目から最終行まで回す
　　For j = 2 To mstSht.Cells(Rows.Count, "A").End(xlUp).Row
　　　If tgtSht.Cells(i, "A").Value = mstSht.Cells(j, "A").Value And _
　　　　 tgtSht.Cells(i, "B").Value = mstSht.Cells(j, "B").Value Then
　　　　 tgtSht.Cells(i, "E").Value = mstSht.Cells(j, "C").Value
　　　　Exit For '見つかれば抜ける
　　　End If
　　Next j
　Next i
　
End Sub
'=====↑　ココマデ　↑===============================================

ただし、上のように
その都度セルから読み込んで、その都度セルに書き出す方式だと
データ数やグループ数が多い場合には時間がかかります。

下のように、配列に一気に読み込んで一気に書き出せば
所要時間はかなり少なくなります。

'=====↓　ココカラ　↓===============================================
Sub Sample2()

　Dim mstAry As Variant
　Dim tgtAry As Variant
　Dim rtnAry As Variant
　Dim i　　　As Long
　Dim j　　　As Long
　
　'グループ分け分類のデータを一気に読み込む
　With Workbooks("グループ分け分類.xls").Worksheets("Sheet1")
　　mstAry = .Range(.Cells(2, "A"), .Cells(.Rows.Count, "C").End(xlUp))
　End With
　
　'結合データのデータを一気に読み込む
　With Workbooks("結合データ.xls").Worksheets("Sheet1")
　　tgtAry = .Range(.Cells(2, "A"), .Cells(.Rows.Count, "B").End(xlUp))
　End With
　
　'書き出しデータ用の配列を用意する
　ReDim rtnAry(1 To UBound(tgtAry), 1 To 1)
　
　For i = 1 To UBound(tgtAry)
　　For j = 1 To UBound(mstAry)
　　　If tgtAry(i, 1) = mstAry(j, 1) And tgtAry(i, 2) = mstAry(j, 2) Then
　　　　rtnAry(i, 1) = mstAry(j, 3)
　　　　Exit For
　　　End If
　　Next j
　Next i
　
　'E2セル以下に結果を一気に書き出す
　Workbooks("結合データ.xls").Worksheets("Sheet1") _
　　.Range("E2").Resize(UBound(tgtAry), 1).Value = rtnAry
　
End Sub
'=====↑　ココマデ　↑===============================================

以上ご参考まで。

マクロで検索条件２つのデータを探してくるには

質問の表現の意味ががはっきりしない。

この回答への補足

今更ですが…。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング