AS2.0orAS3.0でリアルタイムカウンター

リアルタイムでカウンターが増加していくスクリプトを教えていただきたいです！

仕組み的には、0からMAX（任意の値）まで、1秒ごとに増加していくカウンターです。
スタートが、１月１日０時００分００秒。ゴールが１２月３１日２４時００分００秒。
この仕組みを使用した理想のモノが「日本の借金時計」なんですが、スクリプトがわからないのです。。。

http://www.takarabe-hrj.co.jp/clockabout.html

１月中旬までに必要で大変困っています（ToT）

ご回答よろしくお願いします！

No.1 回答者： BlurFiltan 回答日時： 2010/12/23 06:07

「日本の借金時計」のスクリプトやデータ取得システムがどうなっているのかは知りませんが，

ご質問に書かれていらっしゃるような内容のことでしたら
比較的簡単にできるように思います。

ActionScript 3.0 で
新規ドキュメント を作成し
フレーム1 にコピペして
そのまま ムービープレビュー または パブリッシュ する例です↓。

----------------------------------
//目標数値(金額)を設定(仮：1000億)
var goal_yen:Number = 100000000000;

//---テキストフィールド「yen_txt」を用意---
//(手動で用意しても良いです)
var yen_txt:TextField = new TextField();
//適当に設定
yen_txt.border = true;
yen_txt.background = true;
yen_txt.autoSize = "right";
//適当に座標を指定
yen_txt.x = stage.stageWidth - 20;
yen_txt.y = 10;
addChild(yen_txt);

//今の時刻オブジェクト
var now_date:Date = new Date();
//今年の年
var now_year:uint = now_date.getFullYear();

//今年の最初の時刻オブジェクト
var start_date:Date = new Date();
start_date.setFullYear(now_year,0,1);
start_date.setHours(0,0,0,0);
//今年の最初の1971年からの経過ミリ秒
var start_time:Number = start_date.getTime();

//来年の最初(今年の最後)の時刻オブジェクト
var goal_date:Date = new Date();
goal_date.setFullYear(now_year+1,0,1);
goal_date.setHours(0,0,0,0);
//来年の最初の1971年からの経過ミリ秒
var goal_time:Number = goal_date.getTime();

//１ミリ秒辺りのアップ量
var yen_per_ms:Number = goal_yen/(goal_time-start_time);

//毎フレーム時間ごとに関数countUpを実行
this.addEventListener(Event.ENTER_FRAME,countUp);

//関数countUpの定義
function countUp(evt:Event):void {
//今の時刻オブジェクト
var now_date:Date = new Date();
//今の1971年からの経過ミリ秒
var now_time:Number = now_date.getTime();
//今の今年の始めからの経過ミリ秒
var past_time = now_time - start_time;
//テキストフィールドにアップ量を表示
yen_txt.text = String(Math.round(past_time * yen_per_ms));
}
----------------------------------
　

この回答への補足

ご回答有難うございます！！

もし可能であれば、AS2.0の場合も知りたいのですが★
よろしくお願いします！

補足日時：2010/12/28 19:06