パブリッシュ設定でflash player6 → 7に変更したら一部動作しなくなった

Question

こんにちは。いつも貴重なアドバイスを参考にさせて頂いております。さっそくですが、
パブリッシュ設定で書出しバージョンを6から7に変更した所、一部動作しなくなりました。変更した理由は、外部のjpegファイルをターゲットMCにロードしようと思い(スライドショーの様なイメージです)--loadMovie("1.jpg",target_mc)--などでこちらの意図通りの動きをつけたのですが、サイトにアップするとプリローダが動作しない事に気づきました。プレビューでは動作していたので、よけい紛らわしかったのですが、調べた所、loadMovieではロードの進捗状況を把握できない事がわかりました。なのでloadClip()を使うことにしたのですが、タイトルの通りplayer7で書出しすると、一部動作しなくなりました。
おそらく
変数のvar宣言や、型の指定を追記すれば動く(憶測ですが)と思うのですが、その他に注意すべきところはありますでしょうか。actionscript辞書や、検索サイトで色々調べましたがどうもこれというのがみつかりませんでした。やはりガイドブック買わないといけないのかな、と思っています。皆さんは何を参考にされていますでしょうか。よろしければお聞かせ下さい。

DPE · Accepted Answer

loadClip の使い方を間違えていませんでしょうか？
loadClip は loadMovie とは違い、new MovieClipLoader で MovieClipLoader クラスのオブジェクトを作らないと使用できません。
基本的な読み込みのスクリプトは、次のようになります。

（↓各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）


　//オブジェクトを作成
　load_obj = new MovieClipLoader();

　//画像の読み込み
　load_obj.loadClip( "***.jpg" , target_mc );


MovieClipLoader で読み込んだ時は、このクラスが持っている getProgress という機能（メソッドといいます）か、特有のイベント onLoadProgress を利用して進捗状況を把握できます。
onLoadProgress は読み込んだデータがハードディスクに書き込まれる度に発生するイベントですが、オフラインでは正常に動かないので、getProgress の方が扱いやすいです。
ただし、getProgress は戻り値が２つあります。値の受け取り方や参照の仕方にはご注意ください。

読み込みの完了を待つ方法は様々ですが、フレーム間をループして作ると完了率の表示なども作りやすいかと思います。
フレーム間をループする方法では、フレームの構成は次のようになります。

　フレーム１：読み込み開始
　フレーム２：完了を待つためのフレーム。スクリプトはなし。
　フレーム３：読み込み終了判定
　フレーム４：普段はここを表示する

この流れに沿ってスクリプトを考えますと、大体、次のようになります。
スクリプトはフレーム１と３に設定します。


　●フレーム１

　　//オブジェクトを作成
　　load_obj = new MovieClipLoader();

　　//画像の読み込み
　　load_obj.loadClip( "load_clip.swf" , target_mc );

　　//完了率算出用オブジェクトを作成
　　prog = new Object();


　●フレーム３

　　//進捗状況を取得
　　prog = load_obj.getProgress( target_mc );
　　loaded = prog.bytesLoaded;
　　total = prog.bytesTotal;

　　//完了率を算出
　　per = Math.floor( loaded / total * 100 );

　　//完了を待つ
　　if( per < 100 )
　　{
　　　gotoAndPlay( _currentframe - 1 );
　　}
　　//完了したら、次のフレームでタイムラインを止める
　　else
　　{
　　　nextFrame();
　　}


先述の通り、MovieClipLoader の getProgress メソッドには戻り値が２つあります。
関数は戻り値を１つしか返せないため、getProgress は、汎用型である Object 型というタイプの変数に値を２つ入れ、この変数１つだけを返すように設計されています。
たとえるなら、カゴを１つ用意してその中に複数の値を入れ、カゴごとやりとりしているようなものです。

上記のスクリプトでは、変数 per に完了率がパーセントで入ります。
プログレスバーや完了率の表示などにご利用ください。
完了率はフレーム３まで表示すればＯＫです。

---------------------------------------------------------

ところで、loadMovie で読み込んだ場合でも、進捗状況を取得する方法は、あるにはあります。
普通のプリロード画面は、_totalframes と _framesloaded プロパティを見てフレーム数を把握する方法と、getBytesTotal と getBytesLoaded メソッドで容量を把握する方法の２通りの作り方があります。
getBytes*** メソッドは実はムービークリップであればどれでも持っているもので、ムービークリップに読み込まれる画像や swf ファイルの総容量とロード済み容量を教えてくれます。
Flash ではムービー自体も _root という名前のムービークリップとして扱いますから、_root の getBytes*** メソッドではムービー全体の読み込みの進捗状況が把握できるというだけなのです。

target_mc に画像を読み込んだ場合、この読み込みの進捗状況は、target_mc が持っている getBytes*** メソッドで把握できます。
loadMovie、MovieClipLoader の loadClip のどちらで読み込んでも利用できます。
上記のスクリプトで、フレーム１の画像を読み込む部分を

　//画像の読み込み
　loadMovie( "load_clip.swf" , target_mc );

フレーム３の進捗状況を取得する部分を

　//進捗状況を取得
　loaded = target_mc.getBytesLoaded();
　total = target_mc.getBytesTotal();

このように変更しても、同じように動作します。
フレーム１のスクリプトを変更せず、loadClip で読み込むようにしていても同じです。


単に、画像を読み込みその進捗状況を把握したいだけなら、使い方がややこしい MovieClipLoader をあえて使う理由はないのかもしれません。
しかし、MovieClipLoader にできて loadMovie にはできないこともたくさんあります。

loadMovie は、読み込みの命令を出したら、あとは知らんぷりです。
一方 MovieClipLoader は、読み込みを始めてから終了するまで終始その処理を監視していて、処理の各段階ごとにイベントを発生させて状況を知らせてくれます。
先の onLoadProgress というイベントもそのうちの１つですが、他にも様々なイベントがあり、loadMovie よりも細かくロードの状況を把握できます。
特に、回線の都合などでダウンロードが失敗した時やファイルが見当たらなかった場合に、onLoadError というイベントでエラーの発生を知らせてくれるのは、loadMovie にはない機能です。

MovieClipLoader では、１つのオブジェクトでいくつもの読み込みを管理できます。
loadMovie は１件分の読み込み命令しか出せません。
例えば５件の読み込みがあり、読み込み完了時に何かをしたい時は、５件分の指示を出しておかなければなりません。
その点 MovieClipLoader なら、最初に１度、読み込みが済んだ時にはこうしてほしいと約束しておくと、５件の読み込み全てに同じ処理を施してくれます。


MovieClipLoader には、このような特長があります。
機会がありましたら、loadMovie ではできない、エラー発生時の対策がある読み込みなども研究してみてください。

DPE · Answer

＃２のお礼欄にあるスクリプトをざっと試してみたところ、HTML に組み込んでも動きましたよ。
「ダウンロードのシミュレート」で動いたことから考えても、スクリプトは問題ないと思います。

ただ、サーバーにアップロードしてブラウザで見ると、バーが伸びたのは最初の１回だけでした。つまり、２回目以降はキャッシュから拾われているようです。
画像も swf ファイルもローカルにあり、オフライン環境で見る場合は読み込みは一瞬で終わるので、ブラウザで見てもバーは伸びません。これは正常な動作です。


キャッシュから拾われないようにするには、適当な数字を作って URL に ? でダミーの引数として連結する方法があります。
xChangeIllust 関数を、次のように変更してみてください。


　xChangeIllust = function()
　{
　　var rnd , filename;

　　//キャッシュからの読み込み防止：
　　//適当な数字を連結して、毎回違うURLを作る
　　rnd = Math.floor( Math.random() * 1000 );
　　filename = "1.jpg?dummy=" + rnd;

　　//画像読み込み開始
　　loadMovie( filename , _root.loader_mc );

　　//ルートのプログレスバーMC ((preloader_mc)) 内のメソッド呼び出し
　　_root.preloader_mc.xPreloader();
　};


例えば、

　1.jpg?dummy=50

と

　1.jpg?dummy=100

は違う URL と見なされますから、キャッシュからは拾われません。
なお、「ムービープレビュー」では URL オープンエラーになります。ブラウザで確認してみてください。


ところで、プリローダが動作しないことで、どのような不具合（例えば、完了率が 100 ％にならないためにムービーが先に進まない・バーが表示されたままになる・しばらく何も表示されない状態が続くなど）があるのでしょうか？
バーのアニメがなくいきなり画像が表示されるのは、これはキャッシュから拾われているだけなので、他に問題がなければ特に気にしなくても構わないと思います。
キャッシュの問題だとすると、onClipEvent(data) や MovieClipLoader を使ったとしても、完了率がいきなり 100 ％になりますから、バーは伸びません。

また、画像の容量にもよるのですが、ADSL などの速い回線をお使いの場合ですと読み込みが一瞬で済んでしまい、スクリプトに誤りはなくてもバーが伸びていかないようにみえることもあります。
これは、何か重い swf ファイルや JPEG 画像を作って試してみると分かりやすいです。


さしあたって、原因として思いつくのはこんなところですが、いずれかに該当しませんでしょうか？

DPE · Answer

＃１です。
loadMovie と getBytes*** に変更して、「ムービープレビュー」の「ダウンロードのシミュレート」およびサーバー経由の両方で確認してみましたが、進捗状況は正常に把握できました。
オンライン環境や loadMovie と組み合わせたから動かないということではなさそうです。


お礼欄のスクリプトを拝見して思ったのですが。

　target_mc.onEnterFrame = function()
　{
　　//進捗状況を取得
　　loaded = this.getBytesLoaded();
　　total = this.getBytesTotal();
　　　　：
　};

というような書き方をなさっていませんでしょうか？

これこそ Flash の仕様なのですが、ムービークリップに画像や swf ファイルを読み込むと、ムービークリップの一部の属性（ _visible など）や持っていた変数等の初期化が行われます。
on*** = function() ・・・の書き方は一種の変数のようなものですから、loadMovie や loadClip を実行した時点でクリアされてなくなってしまい、正常に動作しなくなります。
この書き方をする限り、getBytes*** でも MovieClipLoader の getProgress でも、進捗状況は把握できません。


どうしても on*** = function() ・・・の形式で定義する場合は、_root またはダミーのムービークリップを作るなどして、target_mc 以外のムービークリップの onEnterFrame イベントハンドラを借りて定義してはいかがでしょうか。
もしくは、target_mc に

（↓各行頭に全角のスペースが入っています。コピーする際はご注意ください）


　onClipEvent(data)
　{
　　//進捗状況を取得し、完了率を算出
　　loaded = this.getBytesLoaded();
　　total = this.getBytesTotal();
　　per = Math.floor( loaded / total * 100 );

　　//完了を待って、先に進む
　　if( per >= 100 )
　　{
　　　/*ここに、読み込み完了時の処理を書く*/
　　}
　}


このように、onClipEvent アクションと data イベントを使って設定してみてください。
onClipEvent で設定したスクリプトは、読み込みを実行しても削除されることなく残ります。
data は、ムービークリップに外部からデータを読み込む時に発生するイベントです。loadVariables では最後の変数が読み込まれた時に１度だけですが、loadMovie の時は読み込みの演算が終わるまで数回にわたって発生します。
ただし、data イベントを使ったスクリプトはオフラインでは正常に動きません。「ムービープレビュー」では「表示」→「ダウンロードのシミュレート」にチェックを入れて動作を確認してください。

パブリッシュ設定でflash player6 → 7に変更したら一部動作しなくなった

loadClip の使い方を間違えていませんでしょうか？

＃２のお礼欄にあるスクリプトをざっと試してみたところ、HTML に組み込んでも動きましたよ。

＃１です。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング