コマンドラインの変数取得画面を前に出さない方法

VBAでコマンドラインを使って表示された文字の取得を行いたいのですが

Set wExec = WSH.Exec("%ComSpec% /c " & """" & sCmd & """")
Do While wExec.Status = 0
DoEvents
Loop
Result = wExec.StdOut.ReadAll

というコードを使って取得を行うことはできるのですが
一瞬だけコマンドプロンプトの画面が表示されるのですが
これが表示されずに文字の取得を行うにはどうしたら良いですか？

No.3 回答者： nicotinism 回答日時： 2015/02/26 22:41

で、結局、両者とも機能しなかったのでしょうか？

結果報告を期待しています！
(-"-)

No.2 回答者： nicotinism 回答日時： 2015/02/23 20:54

あとは一時ファイルに書き出して・・・

Sub sCmdget2()
　　Dim oWS As Object, oFS As Object, v As Variant
　　Dim sCmd As String, sStr As String
　　
　　Set oWS = CreateObject("Wscript.Shell")
　　Set oFS = CreateObject("Scripting.FileSystemObject")
　　
　　sCmd = "dir " & """C:\Program Files (x86)\""" & " /s"
　　
　　oWS.Run "%ComSpec% /c " & sCmd & "> %temp%\Temp.txt", 0, True
　　Set v = oFS.openTextFile(Environ("temp") & "\" & "Temp.txt", 1)
　　sStr = v.readAll
　　v.Close: Set v = Nothing
　　
　　Application.VBE.Windows("イミディエイト").Visible = True
　　Debug.Print sStr
　　Set oFS = Nothing
　　Set oWS = Nothing
Shell "explorer.exe /select, " & Environ("temp") & "\" & "Temp.txt" '出血大サービス？、タスクバー注目
End Sub
ですかね？

この回答へのお礼

ありがとうございます。

お礼日時：2015/02/26 12:46

No.1 回答者： nicotinism 回答日時： 2015/02/23 10:49

これならコマンドプロンプトのウィンドウは寡黙になります。

Sub sCmdget()
　　Dim oWS As Object, sCmd As String, sStr As String
　　
　　Set oWS = CreateObject("Wscript.Shell")
　　sCmd = "dir " & """C:\Program Files (x86)\""" & " /s"
　　oWS.Run "%ComSpec% /c " & sCmd & "|clip", 0 , True
　　sStr = GetObject("\", "htmlfile").ParentWindow.ClipboardData.GetData("text")
　　Application.VBE.Windows("イミディエイト").Visible = True
　　Debug.Print sStr
　　Set oWS = Nothing
End Sub

※ "|clip" はWindowsXPなどでは使用できません。
　Explorer で Clip.exe を検索しても無かったら諦めてください。

この回答へのお礼

ありがとうございます。

この方法だと環境によって使えたり使えなかったりしそうなので
もし他にも方法があれば教えてください。

お礼日時：2015/02/23 17:51