Excel VBA あるセルでENTERを押すと特定のセルへ移動したい

Excel VBAで例えばセル"A2"をセレクトしている状態で
「ENTER」を押すとB5に自動的にセレクトすることはできないでしょうか？

Worksheet_Change関数を使おうと思ったのですが
"A2"の中身が変化しないと発動しません。

Worksheet_SelectionChange関数を使って"A2"を選択している状態で「ENTER」を押すと"A3"が選択されることを利用し、
「"A3"が選択されたら"B5"に飛ぶ」
も考えたのですが、マウスやキーボード操作で"A3"を
選択すると"B5"に飛んでしまうので、これも使えません。

何か対策案はないでしょうか。ご教授よろしくお願いします。

No.2 ベストアンサー 回答者： Wendy02 回答日時： 2005/10/26 20:57

こんばんは。

これは、定番のコードですが、私は、それに、もう少し工夫を凝らしてみました。
本来は、クラスによるインスタンスが良いとは思いますが、それを一般的にお勧めするには、ちょっと荷が重いような気がしました。

'<標準モジュール>

Private Sub ReturnDirectrion2SelectCell()
　If ActiveCell.Address(0, 0) Like "A2" Then
　 Range("B5").Select
　Else
　　'Original ReturnDirection の再現
　 On Error Resume Next
　 Select Case Application.MoveAfterReturnDirection
　　Case xlDown
　　　　ActiveCell.Offset(1).Select
　　Case xlToRight
　　　　ActiveCell.Offset(, 1).Select
　　Case xlToLeft
　　　　ActiveCell.Offset(, -1).Select
　　Case xlUp
　　　　ActiveCell.Offset(-1).Select
　 End Select
　End If
End Sub

Sub SetKeys()
　　'設定用
　　Application.OnKey "~", "ReturnDirectrion2SelectCell"
　　Application.OnKey "{Enter}", "ReturnDirectrion2SelectCell"
End Sub
Sub SetOffKeys()
　'解除用
　Application.OnKey "~"
　Application.OnKey "{Enter}"
End Sub

'-----------------------------------------

自動設定が必要な場合は、以下のコードを加えてください。

'-----------------------------------------
'<標準モジュール>
Sub Auto_Open()
　Call SetKeys
End If
Sub Auto_Close()
　Call SetOffKeys
End If
'-----------------------------------------

なお、現在の設定では、全てのブックの全てのシートに同じように適用されます。Auto_Open等の代わりに、例えば、Worksheet_Activate や Workbook_SheetActivateなどに、SetKeysをCall し、Worksheet_DeactivateやWorkbook_SheetDeactivateに、SetOffKeysをCallするようにすると良いと思います。

この回答へのお礼

ご返事ありがとうございます。
期待していた通りの動作が実現できました。

本当にありがとうございました。

お礼日時：2005/10/26 21:12

No.1 回答者： bdr 回答日時： 2005/10/26 20:07

以下のようにコーディングすればよいのでは

Private blnA2Select As Boolean
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If blnA2Select Then
Range("b5").Select
Else
End If
If Target.Address = "$A$2" Then
blnA2Select = True
Else
blnA2Select = False
End If
End Sub

【注意】
A2がセレクトされた状態から他のセルをセレクトするとB5が選択されるので、「"A2"を選択されている状態で「ENTER」を押すと"B5"を選択する」という要件から若干外れていますが…
「"A2"からフォーカスが外れると"B5"を選択する(「ENTER」に限らず)」
如何でしょう？

この回答へのお礼

ご返信ありがとうございます。

いただいたプログラムを使ってみたところ
「"A2"を選択している状態でマウス操作で"C10"等を選択すると"B5"に飛んでしまう」
という現象が発生してしまいました。

そこで

If blnA2Select Then
Range("b5").Select
Else
↓
If Target.Address = "$A$3" And blnA2Select = True Then
Range("b5").Select
Else

と変更したところ
「前回"A2"で今回"A3"を選択したときのみ"B5"に飛ぶ」
という動作を作ることが出来ました。

理想に近い状態なのですが、キーボード操作で
「"A2"⇒"A3"と移動すると"B5"に飛んでしまう」等
若干問題が残っています。

他によい対策案等ありましたら、ご教授お願いします。

お礼日時：2005/10/26 20:44