エクセル 関数の複数条件設定の仕方教えてください。

H5*0.9<=I5<=H5*1.1　の時には１を
H5*1.1<=I5<=H5*1.2　の時には1.1を
H5*0.8<=I5<=H5*0.9　の時には0.9を

表示する式を是非教えてください。

No.2 回答者： zongai 回答日時： 2009/09/14 23:03

> H5*0.9<=I5<=H5*1.1　の時には１を

> H5*1.1<=I5<=H5*1.2　の時には1.1を
> H5*0.8<=I5<=H5*0.9　の時には0.9を

H5とI5についての条件として書き換えるとこういう事になるのかな？

H5*0.9<=I5　かつ　I5<=H5*1.1　の時には「１」を
H5*1.1<=I5　かつ　I5<=H5*1.2　の時には「1.1」を
H5*0.8<=I5　かつ　I5<=H5*0.9　の時には「0.9」を

で、質問にある条件はちょっとおかしいです。
各々の条件の境界部分、
H5*1.1=I5　だったら、「１」の条件にも「1.1」の条件にも合います。
H5*0.9=I5　だったら、「0.9」の条件にも「１」の条件にも合います。
条件を見直して「<=」のイコールが必要かどうかを確認して下さい。

とりあえず、
H5*1.1=I5　を「1.1」
H5*0.9=I5　を「0.9」
とします。
ついでに条件の順番を変えます。

H5*0.8<=I5　かつ　I5<=H5*0.9　の時には「0.9」を
H5*0.9<I5　かつ　I5<H5*1.1　の時には「１」を
H5*1.1<=I5　かつ　I5<=H5*1.2　の時には「1.1」を

各々をIF分に置き換えて、
=IF(AND(H5*0.8<=I5,I5<=H5*0.9),"0.9","範囲外")
=IF(AND(H5*0.9<I5,I5<H5*1.1),"１","範囲外")
=IF(AND(H5*1.1<=I5,I5<=H5*1.2),"1.1","範囲外"

※結果の数字の「１」が全角だったので、文字扱いにしています。

これを1つの式にするとき、単に"範囲外"のときの処理として組み込めば
=IF(AND(H5*0.8<=I5,I5<=H5*0.9),"0.9",IF(AND(H5*0.9<I5,I5<H5*1.1),"１",IF(AND(H5*1.1<=I5,I5<=H5*1.2),"1.1","範囲外")))

ここから更に整理できそうですが、とりあえずの回答と言うことで。

No.1 回答者： a987654 回答日時： 2009/09/14 22:55

ＩＦ文と関数と両方可能ですがI5<H5*0.8、I5>H5*1.2はどうするの

でしょうか？
又I5=H5*0.9、I5=H5*1.1はどちらに入るのでしょうか？
もう少し慎重な質問をお願いします。

勝手に以下
H5*0.8>I5　の時には0.9を
H5*0.8<=I5<H5*0.9　の時には0.9を
H5*0.9<=I5<H5*1.1　の時には１を
H5*1.1<=I5<H5*1.2　の時には1.1を
I5>=H5*1.2　の時には1.2を
として置き換えさせてもらいます。

ＩＦ文：　=IF(H5*0.8>I5,0.8,IF(H5*0.9>I5,0.9,IF(H5*1.1>I5,1,IF(H5*1.2>I5,1.1,1.2))))

関数：　=(H5*0.8>I5)*0.8+AND(H5*0.8<=I5,I5<H5*0.9)*0.9+AND(H5*0.9<=I5,I5<H5*1.1)*1+AND(H5*1.1<=I5,I5<H5*1.2)*1.1+(I5>=H5*1.2)*1.2